《纸上谈兵·solidity》第 13 课：Solidity 低级调用 call/delegatecall/staticcall —— 直接和 EVM“对话”

CALL(gas, to, value, in_offset, in_size, out_offset, out_size)

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

contract Callee {
    uint256 public value;

    event ValueSet(uint256 newValue);

    function setValue(uint256 _v) external payable {
        value = _v;
        emit ValueSet(_v);
    }

    function getValue() external view returns (uint256) {
        return value;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

contract Caller {
    // 通过 call 调用 setValue
    function callSetValue(address _callee, uint256 _v) external payable {
        (bool success, ) = _callee.call(
            abi.encodeWithSignature("setValue(uint256)", _v)
        );
        require(success, "call failed");
    }

    // 通过 staticcall 调用 getValue
    function callGetValue(address _callee) external view returns (uint256) {
        (, bytes memory data) = _callee.staticcall(
            abi.encodeWithSignature("getValue()")
        );
        return abi.decode(data, (uint256));
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

contract Logic {
    uint256 public value;

    function setValue(uint256 _v) external {
        value = _v;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

contract Proxy {
    uint256 public value;

    function delegateSetValue(address _logic, uint256 _v) external {
        (bool success, ) = _logic.delegatecall(
            abi.encodeWithSignature("setValue(uint256)", _v)
        );
        require(success, "delegatecall failed");
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "forge-std/Test.sol";
import "../src/Callee.sol";
import "../src/Caller.sol";
import "../src/Logic.sol";
import "../src/Proxy.sol";

contract LowLevelCallTest is Test {
    Callee callee;
    Caller caller;
    Logic logic;
    Proxy proxy;

    function setUp() public {
        callee = new Callee();
        caller = new Caller();
        logic = new Logic();
        proxy = new Proxy();
    }

    function testCallSetValue() public {
        caller.callSetValue(address(callee), 42);
        assertEq(callee.value(), 42);
    }

    function testStaticCallGetValue() public {
        caller.callSetValue(address(callee), 99);
        uint256 v = caller.callGetValue(address(callee));
        assertEq(v, 99);
    }

    function testDelegateCall() public {
        proxy.delegateSetValue(address(logic), 123);
        assertEq(proxy.value(), 123);
        assertEq(logic.value(), 0); // Logic 本身不变
    }
}

➜  counter git:(main) ✗ forge test --match-path test/LowLevelCall.t.sol -vvv
[⠊] Compiling...
[⠊] Compiling 2 files with Solc 0.8.29
[⠒] Solc 0.8.29 finished in 1.91s
Compiler run successful!

Ran 3 tests for test/LowLevelCall.t.sol:LowLevelCallTest
[PASS] testCallSetValue() (gas: 39545)
[PASS] testDelegateCall() (gas: 41920)
[PASS] testStaticCallGetValue() (gas: 41426)
Suite result: ok. 3 passed; 0 failed; 0 skipped; finished in 11.37ms (7.34ms CPU time)

Ran 1 test suite in 616.04ms (11.37ms CPU time): 3 tests passed, 0 failed, 0 skipped (3 total tests)

addr.call(data); // ❌ 忽略 success

(bool success, bytes memory ret) = addr.call(data);
require(success, "call failed");