这款水着色器的哪一部分是透明的？

Question

我在这里有一个水着色器，我想知道什么代码是负责透明度。

目前的水是透明的，这是我想要改变的另一件事。我希望RenderType是“RenderType”=“透明”，但它是“RenderType”=“不透明”.我在这个阴影里找不到透明的代码。

也许你知道代码的部分是透明的？

这是水帘

Shader "FX/Water" {
 Properties {
     _WaveScale ("Wave scale", Range (0.02,0.15)) = 0.063
     _ReflDistort ("Reflection distort", Range (0,1.5)) = 0.44
     _RefrDistort ("Refraction distort", Range (0,1.5)) = 0.40
     _RefrColor ("Refraction color", COLOR)  = ( .34, .85, .92, 1)
     [NoScaleOffset] _Fresnel ("Fresnel (A) ", 2D) = "gray" {}
     [NoScaleOffset] _BumpMap ("Normalmap ", 2D) = "bump" {}
     WaveSpeed ("Wave speed (map1 x,y; map2 x,y)", Vector) = (19,9,-16,-7)
     [NoScaleOffset] _ReflectiveColor ("Reflective color (RGB) fresnel (A)", 2D) = "" {}
     _HorizonColor ("Simple water horizon color", COLOR)  = ( .172, .463, .435, 1)
     [HideInInspector] _ReflectionTex ("Internal Reflection", 2D) = "" {}
     [HideInInspector] _RefractionTex ("Internal Refraction", 2D) = "" {}

     //
     _EmissionColor("Color", Color) = (0.000000,0.000000,0.000000,1.000000)
     _EmissionMap("Emission", 2D) = "white" { }
     [Toggle] _DynamicEmissionLM("Dynamic Emission (Lightmapper)", Int) = 0
 }


 // -----------------------------------------------------------
 // Fragment program cards


 Subshader {
     Tags { "WaterMode"="Refractive" "RenderType"="Opaque" }
     Pass {
 CGPROGRAM
 #pragma vertex vert
 #pragma fragment frag
 #pragma multi_compile_fog
 #pragma multi_compile WATER_REFRACTIVE WATER_REFLECTIVE WATER_SIMPLE

 #if defined (WATER_REFLECTIVE) || defined (WATER_REFRACTIVE)
 #define HAS_REFLECTION 1
 #endif
 #if defined (WATER_REFRACTIVE)
 #define HAS_REFRACTION 1
 #endif


 #include "UnityCG.cginc"

 uniform float4 _WaveScale4;
 uniform float4 _WaveOffset;

 #if HAS_REFLECTION
 uniform float _ReflDistort;
 #endif
 #if HAS_REFRACTION
 uniform float _RefrDistort;
 #endif

 struct appdata {
     float4 vertex : POSITION;
     float3 normal : NORMAL;
 };

 struct v2f {
     float4 pos : SV_POSITION;
     #if defined(HAS_REFLECTION) || defined(HAS_REFRACTION)
         float4 ref : TEXCOORD0;
         float2 bumpuv0 : TEXCOORD1;
         float2 bumpuv1 : TEXCOORD2;
         float3 viewDir : TEXCOORD3;
     #else
        float2 bumpuv0 : TEXCOORD0;
         float2 bumpuv1 : TEXCOORD1;
         float3 viewDir : TEXCOORD2;
     #endif
     UNITY_FOG_COORDS(4)
 };

 v2f vert(appdata v)
 {
     v2f o;
     o.pos = UnityObjectToClipPos(v.vertex);


     // scroll bump waves
     float4 temp;
     float4 wpos = mul (unity_ObjectToWorld, v.vertex);
     //temp.xyzw = wpos.xzxz * _WaveScale4 + _WaveOffset;
     temp.xyzw = wpos.yzyz * _WaveScale4 + _WaveOffset;
     o.bumpuv0 = temp.xy;
     o.bumpuv1 = temp.wz;

     // object space view direction (will normalize per pixel)
     o.viewDir.xzy = WorldSpaceViewDir(v.vertex);

     #if defined(HAS_REFLECTION) || defined(HAS_REFRACTION)
     o.ref = ComputeNonStereoScreenPos(o.pos);
     #endif

     UNITY_TRANSFER_FOG(o,o.pos);
     return o;
 }

 #if defined (WATER_REFLECTIVE) || defined (WATER_REFRACTIVE)
 sampler2D _ReflectionTex;
 #endif
 #if defined (WATER_REFLECTIVE) || defined (WATER_SIMPLE)
 sampler2D _ReflectiveColor;
 #endif
 #if defined (WATER_REFRACTIVE)
 sampler2D _Fresnel;
 sampler2D _RefractionTex;
 uniform float4 _RefrColor;
 #endif
 #if defined (WATER_SIMPLE)
 uniform float4 _HorizonColor;
 #endif
 sampler2D _BumpMap;

 half4 frag( v2f i ) : SV_Target
 {
     i.viewDir = normalize(i.viewDir);

     // combine two scrolling bumpmaps into one
     half3 bump1 = UnpackNormal(tex2D( _BumpMap, i.bumpuv0 )).rgb;
     half3 bump2 = UnpackNormal(tex2D( _BumpMap, i.bumpuv1 )).rgb;
     half3 bump = (bump1 + bump2) * 0.5;

     // fresnel factor
     half fresnelFac = dot( i.viewDir, bump );

     // perturb reflection/refraction UVs by bumpmap, and lookup colors

     #if HAS_REFLECTION
     float4 uv1 = i.ref; uv1.xy += bump * _ReflDistort;
     half4 refl = tex2Dproj( _ReflectionTex, UNITY_PROJ_COORD(uv1) );
     #endif
     #if HAS_REFRACTION
     float4 uv2 = i.ref; uv2.xy -= bump * _RefrDistort;
     half4 refr = tex2Dproj( _RefractionTex, UNITY_PROJ_COORD(uv2) ) * _RefrColor;
     #endif

     // final color is between refracted and reflected based on fresnel
     half4 color;

 #if defined(WATER_REFRACTIVE)
     half fresnel = UNITY_SAMPLE_1CHANNEL( _Fresnel,         
      float2(fresnelFac,fresnelFac) );
     color = lerp( refr, refl, fresnel );
     #endif

     #if defined(WATER_REFLECTIVE)
     half4 water = tex2D( _ReflectiveColor, float2(fresnelFac,fresnelFac) );
     color.rgb = lerp( water.rgb, refl.rgb, water.a );
     color.a = refl.a * water.a;
     #endif

     #if defined(WATER_SIMPLE)
     half4 water = tex2D( _ReflectiveColor, float2(fresnelFac,fresnelFac) );
     color.rgb = lerp( water.rgb, _HorizonColor.rgb, water.a );
     color.a = _HorizonColor.a;
     #endif

     UNITY_APPLY_FOG(i.fogCoord, color);

     //o.Emission = c.rgb * tex2D(_Illum, IN.uv_Illum).a;


     return color;
 }
 ENDCG

     }
 }

 }

Answer 1

根据全局配置，#pragma multi_compile WATER_REFRACTIVE WATER_REFLECTIVE WATER_SIMPLE行允许脚本具有不同的模式。从文件中：

multi_compile如何工作 示例指令： #语用multi_compile FANCY_STUFF_OFF FANCY_STUFF_ON 此示例指令生成两个着色器变体:一个具有FANCY_STUFF_OFF定义，另一个带有FANCY_STUFF_ON。在运行时，联合基于材料或全局着色器关键字激活其中一个。如果这两个关键字都没有启用，那么Unity将使用第一个关键字(在本例中为FANCY_STUFF_OFF)。

因此，在这个问题中，默认情况下启用了WATER_REFRACTIVE。

如果您查看片段着色器，您将看到以下#ifdefined部分：

#if defined(WATER_REFRACTIVE)
half fresnel = UNITY_SAMPLE_1CHANNEL( _Fresnel,         
float2(fresnelFac,fresnelFac) );
color = lerp( refr, refl, fresnel );
#endif

要回答眼前的问题，透明效果是折射色refr在反射色refl上可见的位置，反射色refl是由_Fresnel和_BumpMap纹理决定的。

你可以让水完全反射，改变这里的着色器，只使用color = refl;。

但是，另一种方法是通过在Material.EnableKeyword的Material上使用WATER_SIMPLE关键字来更改着色器的模式：

water.material.EnableKeyword("WATER_SIMPLE"); 

这样做将在顶点着色器中使用这个#ifdefined部分，而不是前面提到的：

​

#if defined(WATER_SIMPLE)
half4 water = tex2D( _ReflectiveColor, float2(fresnelFac,fresnelFac) );
color.rgb = lerp( water.rgb, _HorizonColor.rgb, water.a );
color.a = _HorizonColor.a;
#endif

我们可以看到，它将输出颜色的alpha设置为_HorizonColor.a。这意味着在这种模式下，您可以通过更改_HorizonColor的alpha值来直接设置水的透明度