在sortCompareFunction中跨DataGridColumns重用AS3

Question

我使用以下函数组装了一个DataGrid

 public function get dataGridColumns():Array {
    var dataGridColumnArray:Array = [];
    dataGridColumnArray.push(createDataGridColumn(col1, "field1", 0.17, sortStrings));
    dataGridColumnArray.push(createDataGridColumn(col2, "field2", 0.17, sortStrings));
    dataGridColumnArray.push(createDataGridColumn(col3, "field3", 0.17, sortStrings));
    return dataGridColumnArray;
}

private static function createDataGridColumn(columnName:String, dataField:String, width:Number,sortCompareFunction:Function = null):DataGridColumn {
    var column:DataGridColumn = new DataGridColumn(columnName);
    column.dataField = dataField;
    column.width = width;
    column.sortCompareFunction = sortCompareFunction;
    return column
}

private function sortStrings(a:Object, b:Object, fields:Array = null):int{
    if(a.toString().toLowerCase() > b.toString().toLowerCase()){
        return 1;
    }else if(a.toString().toLowerCase() < b.toString().toLowerCase()){
        return -1;
    }else{
        return 0;
    }
}

由于我的dataProvider是一个数据对象数组，所以我遇到了排序函数中的a和b是对象的问题，我希望以某种方式将数据字段(列标题)传递到排序中，这样我就可以使用一个排序函数来检查正确的对象属性，这样它看起来就像：

private function sortStrings(a:Object, b:Object, field:String):int{
    if(a.field.toLowerCase() > b.field.toString().toLowerCase()){
        return 1;
    }else if(a.field.toString().toLowerCase() < b.field.toString().toLowerCase()){
        return -1;
    }else{
        return 0;
    }
}

我还没有想出一个很好的方法来做这件事，最坏的情况是，我有6个非常相似的排序函数。

Answer 1

您可以创建一个比较器工厂函数，它将返回闭包，并包含字段名：

private function createComparatorFor(field:String):Function {
    return function (a:Object, b:Object, fields:Array = null):int{
        const aField:String = a[field].toString().toLowerCase();
        const bField:String = b[field].toString().toLowerCase();

        if (aField > bField) {
            return 1;
        }

        if (aField < bField) {
            return -1;
        }

        return 0;
    }
}

像这样使用它：

dataGridColumnArray.push(createDataGridColumn(
    col1, "field1", 0.17, createComparatorFor("field1")));

未经测试，但应该有效