切片XMLList而不是数组

Question

如何从我的xmllist中获得类似于数组的片方法的一系列项？

切片(startIndex，endIndex)；

我正在尝试这样的方法：

            var tempXMLList:XMLList = new XMLList();

            for( var i:int = startIndex; i <= endIndex; i++){
                tempXMLList += originalList[i];
            }

但是我得到了一个错误，它不能转换originalListi

-最新消息

我用了提摩菲的函数，它工作得很好。

private function SliceXMLList(xmllist : XMLList, startIndex : int, endIndex : int) : XMLList
{
    return xmllist.(childIndex() >= startIndex && childIndex() <= endIndex);
}

但是，当我使用已经过滤的xmllist时，它会中断。

filteredData = filteredData.(team == "Ari");

trace("filteredData.length(): " + filteredData.length().toString());
pData = SliceXMLList(filteredData, startIndex, endIndex);
trace("start: " + startIndex.toString() + " end: " + endIndex.toString());
trace("pdata length: " + pData.length().toString());

输出

filteredData.length(): 55
start: 0 end: 55
pdata length: 5

Answer 1

使用e4x。

private function SliceXMLList(xmllist : XMLList, startIndex : int, endIndex : int) : XMLList
{
    return xmllist.(childIndex() >= startIndex && childIndex() <= endIndex);
}

更新：

如果要在一些e4x排序之后使用这个函数，就会出现一个问题，因为childIndex()函数返回节点索引的旧值，因此不能更改它。所以，我有另一个想法：

private function SliceXMLList(xmllist : XMLList, startIndex : int, endIndex : int) : XMLList
{
    for (var i : int = 0; i < xmllist.length(); i++)
        xmllist[i].@realIndex = i;
    xmllist =  xmllist.(@realIndex >= startIndex && @realIndex <= endIndex);
    for (i = 0; i < xmllist.length(); i++)
        delete xmllist[i].@realIndex;
    return xmllist;
}

或者只是

private function SliceXMLList(xmllist : XMLList, startIndex : int, endIndex : int) : XMLList
{
    var newXMLList : XMLList = new XMLList();
    var currIndex : int = 0;
    for (var i : int = startIndex; i <= endIndex; i++)
        newXMLList[currIndex++] = xmllist[i];
    return newXMLList;
}

我认为这是最好的变体。当然，一行e4x语句要优雅得多，但不幸的是，它不能重用。

Answer 2

不确定您期望它如何工作，但是您可以遍历所有的子程序，并将每个子程序保存到一个数组中，然后以这种方式对它们进行修剪。