首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >同时计算多个变量的增长率

问同时计算多个变量的增长率
EN

Stack Overflow用户
提问于 2020-01-22 23:26:13
回答 3查看 119关注 0票数 1

我想计算几个变量的增长率,而不是手动计算。有没有什么聪明的方法呢?

例如,请参阅sashelp.citiyr的下表,如下所示:

代码语言:javascript
复制
DATE    PAN     PAN17   PAN18   PANF    PANM
1980    227757  172456  138358  116869  110888
1981    230138  175017  140618  118074  112064
1982    232520  177346  142740  119275  113245
1983    234799  179480  144591  120414  114385
1984    237001  181514  146257  121507  115494
1985    239279  183583  147759  122631  116648
1986    241625  185766  149149  123795  117830
1987    243942  187988  150542  124945  118997
1988    246307  189867  152113  126118  120189
1989    248762  191570  153695  127317  121445

我可以创建变量的增长率,如下所示(例如第一列PAN),但我想要一种方法来计算所有变量(或者我想要的变量,想象一个有几十个变量的情况)。

代码语言:javascript
复制
data test; 
    set sashelp.citiyr; 
    by date;
    Pan_growth = PAN / lag(PAN);
run;

你知道怎么让这个更聪明吗?

EN

回答 3

Stack Overflow用户

回答已采纳

发布于 2020-01-23 00:04:23

使用数组。

代码语言:javascript
复制
data test;
    set sashelp.citiyr;

    array vars[*]   pan pan17 pan18 panf panm;
    array growth[*] pan_growth pan17_growth pan18_growth panf_growth panm_growth;

    do i = 1 to dim(vars);
        growth[i] = vars[i]/lag(vars[i]);
    end;
run;

如果您的变量都以某个前缀开头,以序列号结束,或者总是以完全相同的顺序结束,那么使用variable list shortcuts可以节省更多的时间。

如果您有更复杂的情况,您有成百上千的变量没有正确的顺序或没有简单的模式,您可以生成所需的名称并使用SQL和dictionary.columns将它们保存到宏列表中。只需确保从查询中排除任何不相关的变量即可。

代码语言:javascript
复制
proc sql noprint;
    select name
         , cats(name, '_growth')
    into :vars separated by ' '
       , :growth_vars separated by ' '
    from dictionary.columns
    where     libname = 'SASHELP'
          AND memname = 'CITIYR'
          AND upcase(name) NE 'DATE'
    ;
quit;

data test2;
    set sashelp.citiyr;

    array vars[*]   &vars.;
    array growth[*] &growth_vars.;

    do i = 1 to dim(vars);
        growth[i] = vars[i]/lag(vars[i]);
    end;
run;
票数 1
EN

Stack Overflow用户

发布于 2020-01-23 01:59:05

转置您的数据集,并通过组处理使用。

代码语言:javascript
复制
   *transpose to a long format;
   proc transpose data=have out=long (rename=col1=Value);
   by date;
   var pan--panm;
   run;

   *sort for each variable to be consistent;
   proc sort data=long;
   by _name_ date;
   run;

   *calculate lag;
   data want;
   set long;
   by _name_;
   prev_val = lag(value);


   if not(first._name_) then growth = value/prev_value - 1;
   run;
票数 2
EN

Stack Overflow用户

发布于 2020-01-23 15:56:48

你可以使用宏。此外,为了避免出现警告,您需要一些条件逻辑来防止第一行中的除法

代码语言:javascript
复制
data test; 
    set sashelp.citiyr; 
    by date;
    %macro growth(var);
        before=lag(&var);
        if _N_>1 then &var._growth = &var. / before;
        drop before;
    %mend;
    %growth(PAN);
    %growth(PAN17);
    %growth(PAN18);
    %growth(PANF);
    %growth(PANM);
run;
票数 2
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/59863038

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档