在SAS中删除gchart的轴值

Question

我正在尝试使用SAS中的gchart绘制分类的条形图。我在横轴上有日期，所以我不想出现，因为看起来很混乱。我使用了下面的代码

axis1 label=none value=none;                                                                                                            


axis2 label=(angle=90 'Porcentaje');                                                                                                       


legend1 label=('Categoría') frame;                                                                                                       

proc gchart data=base_fechas;                                                                                                                  
   vbar REPORTE_FCH/ discrete subgroup=TPO_SEX                                                                                             
                 group=REPORTE_FCH  g100 nozero                                                                                               
                  type=percent                                                                                                
                 inside=percent width=20                                                                                                
                 gaxis=axis1 raxis=axis2                                                                                                
                 legend=legend1;                                                                                                        
run;                                                                                                                                    
quit;   

但是轴的值仍然很接近。如何删除水平轴的DE值？

Answer 1

你有vbar <date> / … group=<date> g100 … ;

group=<date>轴渲染由gaxis选项控制。vbar <date>是中间点，它们的渲染由maxis选项控制。

可以通过指定vbar选项maxis=axis1来隐藏中点

此示例同时隐藏中点和组：

data have;

  do date = today()-100 to today();
    do index = 1 to 50 * ranuni(123);

      sex = substr('MF',1+(rannor(123) > 0.75),1);
      output;

    end;
  end;

  format date yymmdd10.;
run;

axis1 label=none value=none;
axis2 label=(angle=90 '%');

proc gchart data=have;
  vbar date
  / discrete
    subgroup = sex
    GROUP = date
    G100
    nozero
    type=percent
    inside=percent width=20

    gaxis = axis1 
    raxis = axis2
    maxis = axis1
  ;

  where date > today()-20;
run;