将XLSM保存到XLSX

Question

我正在努力将我的XLSM转换成XLSX之前是转换成File..it，我试图改变一点，但没有成功。

我想使用与工作簿相同的名称，但只使用XLSX格式。

Sub xlsmtoxlsx()
Dim PathFile As String
Dim PathArray() As String
Dim PathPDF As String
   
'Get file path
PathFile = Application.ThisWorkbook.FullName

'Split file path in path and file ending
PathArray() = Split(PathFile, ".")

'Creat file path with ".pdf" ending
PathPDF = PathArray(0) & ".xlsx"
    
'PDF File is saved in directory of workbook
ActiveSheet.ExportAsFixedFormat Type:=xlTypeXlsx, Filename:= _
    PathPDF, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
    :=False, OpenAfterPublish:=True
    
'Closes Workbook after generating PDF
ActiveWorkbook.Saved = True
Application.Quit

Answer 1

备份为XLSX

Option Explicit

Sub BackupAsXLSX()
    
    ' Create a reference to the source workbook.
    Dim swb As Workbook: Set swb = ThisWorkbook ' workbook containing this code
    
    ' Determine the destination file path ('FullName').
    Dim sFilePath As String: sFilePath = swb.FullName
    Dim DotPosition As Long: DotPosition = InStrRev(sFilePath, ".")
    Dim dFilePath As String: dFilePath = Left(sFilePath, DotPosition) & "xlsx"
    
    Application.ScreenUpdating = False
    
    ' Copy all sheets to a new (destination) workbook.
    swb.Sheets.Copy
    Dim dwb As Workbook: Set dwb = ActiveWorkbook
    ' Save and close the destination workbook.
    Application.DisplayAlerts = False ' overwrite without confirmation
    dwb.SaveAs Filename:=dFilePath, FileFormat:=xlOpenXMLWorkbook
    Application.DisplayAlerts = True
    dwb.Close SaveChanges:=False
    
    Application.ScreenUpdating = True
    
    ' Inform.
    MsgBox "XLSX backup created.", vbInformation
    
    ' Note that the source workbook hasn't been modified in any way.
    
End Sub