Prolog比

Question

在Prolog中找出谁是最高的最简单的方法是什么：

height(lisa,1.65).
height(sam,1.70).
height(luke,1.92).
height(nicole,1.54).

我想写

tallest(X) :- Y is bigger than other Y's

Answer 1

height(lisa,1.65).
height(sam,1.70).
height(luke,1.92).
height(nicole,1.54).

max_height(Person, Height, [[Person, Height]]).
max_height(P , H , [[P, H]|Tail]) :- max_height(_ , H2, Tail), H  > H2.
max_height(P2, H2, [[_, H]|Tail]) :- max_height(P2, H2, Tail), H =< H2.

tallest(X) :- findall([P, H], height(P, H), Bag), max_height(X, _, Bag).

有几种方法可以避免编写max_height：Prolog, find minimum in a list

Answer 2

SWI-Prolog有一些不同的方法来解决这个问题，例如借助于库(solution_sequences)。

?- order_by([desc(H)],height(P,H)).
H = 1.92,
P = luke ;
...

或使用库(aggregate)：

?- aggregate(max(H,P),height(P,H),max(_,P)).
P = luke.

不太复杂的Prologs可能会提供setof/3和last/2：

?- setof(H:P,height(P,H),L),last(L,_:P).
P = luke,
L = [1.54:nicole, 1.65:lisa, 1.7:sam, 1.92:luke].

和更基本的引擎，缺少setof/3，将提供

?- height(P,H),\+((height(_,L),L>H)).
P = luke,
H = 1.92 ;

Answer 3

假设tallest(X)成功，当且仅当person X比所有其他人都高时，我认为正确的答案应该是：

tallest(X) :-
    height(X, H),
    forall((height(Y, H1),
            X \= Y),
            H > H1), !.

第一个场景：

height(lisa,1.65).
height(sam,1.70).
height(luke,1.92).
height(nicole,1.54).

?- tallest(X).
X = luke.

第二种情况：

height(lisa,   1.65).
height(sam,    1.70).
height(luke,   1.92).
height(nicole, 1.54).
height(bob,    1.92). % Bob is as tall as Luke!

?- tallest(X).
false.