触发自动热键中的Brave“搜索标签”功能

Question

我希望能够触发“搜索标签”从自动热键，因为我有很多打开的标签，这将帮助我快速找到我正在寻找的标签，我知道我可能能够通过脚本循环通过所有标签，但这不是我想要的。

这就是我所做的

!+a::
  WinActivate, Brave
  Sleep, 100
  Send, {Ctrl}{Shift}a
Return

如果我用Send, {Ctrl}t更改Send, {Ctrl}{Shift}a是正确地打开一个标签，那么问题一定是我的{Ctrl}{Shift}a配置中的某个错误，或者Brave不知何故没有反应。

Answer 1

激活特定窗口并向其发送击键的最合适方法如下：

!+a::
    SetTitleMatchMode, 2 ; if you want to use it only in this hotkey
    IfWinNotExist, Brave
    {
        MsgBox, Cannot find Brave
            Return ; end of the hotkey's code
    }
    ; otherwise:
    WinActivate, Brave
    WinWaitActive, Brave, ,2  ; wait 2 seconds maximally  until the specified window is active
    If (ErrorLevel)  ;  if the command timed out
    {
        MsgBox, Cannot activate Brave
            Return
    }
    ; otherwise:
    ; Sleep 300 ; needed in some programs that may not react immediately after activated
    Send, ^+a
Return

否则，脚本会将击键发送到另一个窗口。

为了避免在每个热键中重复整个代码，您可以创建一个函数：

!+b::
    SetTitleMatchMode, 2
    Activate("Brave", 2)
    ; Sleep 300
    Send, ^+a
Return

Activate(title, seconds_to_wait){
    IfWinNotExist, % title
    {
        MsgBox % "Cannot find """ . title . """."
            Return
    }
    ; otherwise:
    WinActivate, % title
    WinWaitActive, % title, ,% seconds_to_wait
    If (ErrorLevel) 
    {
        MsgBox % "Cannot activate """ . title . """."
            Return
    }
}