如何在clojure中更改原子映射？

Question

我是clojure新手，我需要更新这个原子中的两个值：

(def app-state (atom {:id "1":status 0 :st 0}))

我正在使用以下内容：

(let [value (mod (+ (:st @app-state) 1) 4)]
    (swap! app-state update-in [:status] value)
    (swap! app-state update-in [:st] inc))

我得到了：

Caused by: java.lang.ClassCastException: java.lang.Long cannot be cast to clojure.lang.IFn

Answer 1

update-in的第三个参数接受一个函数，但您提供的是一个长参数(value)，这就是为什么会出现异常。您可以改用assoc-in，它直接获取要在映射中关联的值：

(swap! app-state assoc-in [:status] value)

但是，您应该在传递给swap!的函数中以原子方式完成状态的整个更新。

(swap! app-state (fn [{:keys [st] :as state}]
                    (let [st-next (inc st)
                          value (mod st-next 4)]
                       (merge state {:st st-next
                                     :status value}))))

Answer 2

下面是一个基于你的问题的repl会话。首先，我定义的app-state与您发布的完全一样。接下来，我将bump-state定义为一个匿名函数#(…)，它接受一个参数，即app-state的当前值，由%占位符表示。let表单将:st键的递增值绑定到st。最后，assoc通过将新值与前一个映射的:st和:status关联起来，返回一个新的不可变映射。

接下来的几行代码只需调用swap!来确认bump-state是否正常工作。最后一行在对swap!的调用中直接定义了匿名函数。虽然accepted answer运行良好，但我认为这更简洁一些。

user=> (def app-state (atom {:id "1":status 0 :st 0}))
#'user/app-state
user=> (def bump-state #(let [st (inc (:st %))] (assoc % :st st :status (mod st 4))))
#'user/bump-state
user=> (swap! app-state bump-state)
{:id "1", :status 1, :st 1}
user=> (swap! app-state bump-state)
{:id "1", :status 2, :st 2}
user=> (swap! app-state bump-state)
{:id "1", :status 3, :st 3}
user=> (swap! app-state bump-state)
{:id "1", :status 0, :st 4}
user=> (swap! app-state #(let [st (inc (:st %))] (assoc % :st st :status (mod st 4))))
{:id "1", :status 1, :st 5}

swap!的整个思想是，您的更新函数对原子持有的当前不可变值进行操作，并返回一个新的不可变值来替换它。您的update函数只是一个纯函数，它可以让您更容易地推断它，并在repl中使用它，就像其他函数一样。