Google sheets -从两个单独的列进行交叉连接/笛卡尔连接

Question

希望有人能帮助我在谷歌工作表笛卡尔产品。我在两个单独的列中有数据，并希望在单独的选项卡中创建这两个列的所有可能组合。第一列是ID (文本)，第二列是日期格式。输出应该是两个单独的列。公式应该是动态的，即当向输入列表添加新的ID或日期时，列表应该更新。

我已经在网上寻找了解决方案，但还没有找到有效的解决方案。我精通Excel，但不太精通Google Sheet :)

这是一个样例工作表：https://docs.google.com/spreadsheets/d/150uIg3XH1hxZa8vSxDhcVZVOcSEOp175OPYL4Rc-wWI/edit?usp=sharing

Answer 1

使用以下命令：

=ARRAYFORMULA(
  SPLIT(
    FLATTEN(
        FILTER('input 1'!A2:A, 'input 1'!A2:A <> "")
      & ","
      & TRANSPOSE(FILTER('input 2'!A2:A, 'input 2'!A2:A <> ""))
    ),
    ","
  )
)

在单元格A3中，但确保将列B重新格式化为date (复制E列中的格式)：

​

​

Answer 2

我认为soMarios的解决方案在您的情况下更好，但这里有另一个解决方案，只是为了展示一种不同的方法。通过一些工作，这种方法可以推广到任何数量的列。

=ARRAYFORMULA(
  {
    VLOOKUP(
      INT(SEQUENCE(COUNTA('input 1'!A2:A) * COUNTA('input 2'!A2:A), 1,) / COUNTA('input 2'!A2:A)) + 1,
      {SEQUENCE(COUNTA('input 1'!A2:A)), FILTER('input 1'!A2:A, 'input 1'!A2:A <> "")},
      2,
    ),
    VLOOKUP(
      MOD(SEQUENCE(COUNTA('input 1'!A2:A) * COUNTA('input 2'!A2:A), 1,), COUNTA('input 2'!A2:A)) + 1,
      {SEQUENCE(COUNTA('input 2'!A2:A)), FILTER('input 2'!A2:A, 'input 2'!A2:A <> "")},
      2,
    )
  }
)

​

​

Answer 3

尝试：

=INDEX(SPLIT(FLATTEN(
 OFFSET('input 1'!A2,,,COUNTA('input 1'!A2:A))&"♠"&TRANSPOSE(
 OFFSET('input 2'!A2,,,COUNTA('input 2'!A2:A)))), "♠"))

​

​

并将B列的格式设置为日期