如何简化Compojure路由？

Question

我使用以下代码在Compojure中定义我的路由：

(ns my-project.my-test
  (:gen-class)
  (:require
   [my-test.template-views :refer :all]
   [compojure.core :refer [defroutes GET POST context]]
   [compojure.route :as route]
   [org.httpkit.server :refer [run-server]]))

(defn wrap-request
  [handler]
  (fn [request]
    (let [{remote-addr :remote-addr uri :uri scheme :scheme request-method :request-method} request]
      (println (str "REQUEST: " request)))
    (handler request)))

(defroutes app
  (wrap-request
   (GET "/" request
     {:status 200
      :headers {"Content-Type" "text/html"}
      :body (template-body (:uri request))}))
  (wrap-request
    (GET "/page1" request
      {:status 200
       :headers {"Content-Type" "text/html"}
       :body (template-body (:uri request))}))
  (wrap-request
    (GET "/page2" request
      {:status 200
       :headers {"Content-Type" "text/html"}
       :body (template-body (:uri request))}))
  (wrap-request
    (GET "/page3" request
      {:status 200
       :headers {"Content-Type" "text/html"}
       :body (template-body (:uri request))}))
  (route/resources "/")
  (route/not-found {:status 404
                    :headers {"Content-Type" "text/html"}
                    :body "<h1>Not Found</h1>"}))

这是可行的，但看起来我应该能够像这样简化它：

(ns my-project.my-test
  (:gen-class)
  (:require
   [my-test.template-views :refer :all]
   [compojure.core :refer [defroutes GET POST context]]
   [compojure.route :as route]
   [org.httpkit.server :refer [run-server]]))

(defn wrap-request
  [handler]
  (fn [request]
    (let [{remote-addr :remote-addr uri :uri scheme :scheme request-method :request-method} request]
      (println (str "REQUEST: " request)))
    (handler request)))

(defn wrap-template
  [route]
  (wrap-request
   (GET route request
     {:status 200
      :headers {"Content-Type" "text/html"}
      :body (template-body (:uri request))})))

(defroutes app
  (map wrap-template ["/" "/page1" "/page2" "/page3"])
  (route/resources "/")
  (route/not-found {:status 404
                    :headers {"Content-Type" "text/html"}
                    :body "<h1>Not Found</h1>"}))

然而，当我这样做的时候，我得到了这个错误回溯：

Sat Apr 24 22:38:33 MDT 2021 [worker-2] ERROR - GET /page2
java.lang.ClassCastException: class clojure.lang.LazySeq cannot be cast to class clojure.lang.IFn (clojure.lang.LazySeq and clojure.lang.IFn are in unnamed module of loader 'app')
    at compojure.core$routing$fn__368163.invoke(core.clj:185)
    at clojure.core$some.invokeStatic(core.clj:2705)
    at clojure.core$some.invoke(core.clj:2696)
    at compojure.core$routing.invokeStatic(core.clj:185)
    at compojure.core$routing.doInvoke(core.clj:182)
    at clojure.lang.RestFn.applyTo(RestFn.java:139)
    at clojure.core$apply.invokeStatic(core.clj:669)
    at clojure.core$apply.invoke(core.clj:662)
    at compojure.core$routes$fn__368167.invoke(core.clj:192)
    at org.httpkit.server.HttpHandler.run(RingHandler.java:117)
    at java.base/java.util.concurrent.Executors$RunnableAdapter.call(Executors.java:515)
    at java.base/java.util.concurrent.FutureTask.run(FutureTask.java:264)
    at java.base/java.util.concurrent.ThreadPoolExecutor.runWorker(ThreadPoolExecutor.java:1128)
    at java.base/java.util.concurrent.ThreadPoolExecutor$Worker.run(ThreadPoolExecutor.java:628)
    at java.base/java.lang.Thread.run(Thread.java:834)

使用(map)有什么地方出了问题吗？

Answer 1

routes (以及defroutes) expects each argument to be a request handler function。处理程序列表不是处理程序函数；因此出现错误。幸运的是，有一个函数可以将处理程序列表转换为单个处理程序：routes！因为它需要N个独立的参数，而不是一个单独的列表，所以你也需要apply。所以：

(defroutes app
  (apply routes (map wrap-template ["/" "/page1" "/page2" "/page3"]))
  (route/resources "/")
  (route/not-found {:status 404
                    :headers {"Content-Type" "text/html"}
                    :body "<h1>Not Found</h1>"}))

另外，我通常建议不要使用defroutes，原因很简单，因为它不像单独的def + routes那样容易组合，对于初学者来说，它会导致忘记defroutes之外的任何东西存在，而实际上大多数有趣的服务器会想要将一个函数应用到他们的一些路由上。