QMake和pkg-config

Question

我在我的一个Qt应用程序中使用libqtermwidget。碰巧的是，在0.8.0版本的库中引入了一些新功能，而0.6.0版本中没有这些功能。

因为libqtermwidget没有提供任何版本宏，所以我想在qmake中使用pkg-config来检查它的版本，如下所示：

# i would like a functionality like this
if pkg-config --version qtermwidget5 < 0.8.0
    DEFINES += OLD_QTERMWIDGET

当然，这可以在cpp文件中使用：

#ifndef OLD_QTERMWIDGET
    ... code for 0.8.0 and higher ...
#endif

Answer 1

您应该使用$$system()来调用pkg-config并读取标准输出(如果有的话)。但让我们以更“通用”的方式对其进行编程：

# finds package version by invoking 'pkg-config'
# $$1 = package
# note: stores value in cache (stash) file for subsequent use
defineReplace(findPackage) {
    # using <package>Version variable
    pkg = $${1}Version
    !defined($$pkg, var) {
        # cache miss
        # note: $$pkgConfigExecutable() is an undocumented function from qt_functions.prf
        $$pkg = $$system($$pkgConfigExecutable() --modversion $$1)
        # cannot store the empty value
        isEmpty($$pkg): $$pkg = 0
        # save to the stash file
        cache($$pkg, stash)
    }
    # return value of <package>Version
    return($$eval($$pkg))
}


# now using this...
qtw5 = $$findPackage(qtermwidget5)
equals(qtw5, 0) {
    error("qtermwidget5 is not installed")
} else:!versionAtLeast(qtw5, 0.8.0) {
    warning("Found an old version of qtermwidget5 ($$qtw5)")
    DEFINES += OLD_QTERMWIDGET
} else {
    # nothing
}