如何在Scheme中使用语法规则从列表中创建List？

Question

就像我想要转变的练习一样：

(alist "foo" 1 "bar" 2 "baz" 3)

转到

(("foo" . 1) ("bar" . 2) ("baz" . 3))

使用语法规则可以做到这一点吗？

我的尝试是：

(define-syntax alist
  (syntax-rules ()
     ((_ a b) (cons a b))
     ((_ x y ...)
      (list (alist x y) ...))))

它扩展成的问题是：

(("foo" . 2) ("foo" . "bar") ("foo" . 4) ("foo" . "baz") ("foo" . 6))

是否可以使用语法规则来实现宏列表？它应该是什么样子的？

编辑：

另一次尝试

(define-syntax alist
  (syntax-rules ()
     ((_ a b) (cons a b))
     ((_ x y z ...)
      (list (alist x y) (alist z ...)))))

它返回(("foo" . 2) (("bar" . 4) ("baz" . 6)))。

Answer 1

如果它只是文字(比如"foo"和2)，你可以这样做：

#!r6rs
(import (rnrs))

(define-syntax alist
  (syntax-rules (alist-builder)
    ((_ alist-builder () (results ...)) 
     '(results ...))
    ((_ alist-builder (a) . rest) 
     (raise 'bad-alist))
    ((_ alist-builder (a b rest ...) (results ...))
     (alist alist-builder (rest ...) (results ... (a . b))))
    ((_ a ...) (alist alist-builder (a ...) ()))))

(alist)         ; ==> ()
(alist "a" 2)   ; ==> (("a" . 2))
(alist a 3 b 4) ; ==> ((a . 3) (b . 4))
(alist a)       ; ==> uncaught exception: bad-alist

当然，您不允许对此进行更改，因为(alist a b c d)与您不允许更改的字面上的'((a . b) (c . d))是相同的。

此外，如果您曾经使用alist-builder作为第一个键来创建一个列表，那么内部将会泄漏。您可以通过拆分内部定义来修复此问题，也可以通过将两者都放在库中并仅导出alist来隐藏它以避免暴露

Answer 2

我已经弄明白了：

(define-syntax alist
  (syntax-rules ()
     ((_) ())
     ((_ a b) (list (cons a b)))
     ((_ x y z ...)
      (apply list (cons x y) (alist z ...)))))

和简化版本：

(define-syntax alist
  (syntax-rules ()
     ((_) ())
     ((_ a b) (list (cons a b)))
     ((_ x y z ...)
      (cons (cons x y) (alist z ...)))))