如何以编程方式判断系统是R/3还是S/4

Question

是否可以通过代码确定当前系统是R/3还是S/4？

我需要它，因为我有一个返回人力资源相关数据的软件组件的方法，但是这个组件应该不同于R/3和S/4系统。

    DATA(lv_software_component) = mo_configuration->get_software_component( ).

    SELECT * FROM tadir INTO TABLE @DATA(lt_inftype_tables)
            WHERE pgmid  = 'R3TR'
              AND object = 'TABL'
              AND devclass IN ( SELECT devclass FROM tdevc
                                               WHERE dlvunit = @lv_software_component
                                                  OR dlvunit = 'SAP_HRGXX'
                                                  OR dlvunit = 'SAP_HRRXX' )

例如，在R/3上，lv_software_component应该是'SAP_HRCMX'，而在S/4上，它应该是'S4HCMCMX'。目前，我不知道如何从编程的角度来区分这两个版本之间的区别。

我想出的最好的办法是硬编码SY-SYSID，因为我知道哪些系统是S/4，哪些不是，但这不应该是理想的。

感谢大家的帮助，谢谢！

Answer 1

您可以使用下面的类方法来确定它。另一方面，is_s4h方法只存在于S4系统上。在调用方法之前，您需要检查方法是否存在。

cl_cos_utilities=>is_s4h( )

完整的工作示例：

REPORT ZMKY_ISS4.
CLASS cl_oo_include_naming DEFINITION LOAD.

DATA oref TYPE REF TO if_oo_class_incl_naming.
DATA: lt_methods TYPE seop_methods_w_include,
      lv_clskey  TYPE seoclskey,
      ls_cpdkey  TYPE seocpdkey,
      lv_iss4    TYPE abap_bool,
      lt_params  TYPE abap_parmbind_tab.

lv_clskey = 'CL_COS_UTILITIES'.
oref ?= cl_oo_include_naming=>get_instance_by_cifkey( lv_clskey ).
lt_methods = oref->get_all_method_includes( ).
ls_cpdkey-clsname = lv_clskey.
ls_cpdkey-cpdname = 'IS_S4H'.
READ TABLE lt_methods WITH KEY cpdkey = ls_cpdkey TRANSPORTING NO FIELDS.
IF sy-subrc EQ 0.
  lt_params = VALUE #( ( name  = 'RV_IS_S4H'
                  kind  = cl_abap_objectdescr=>returning
                  value = REF #( lv_iss4 ) ) ).
  CALL METHOD CL_COS_UTILITIES=>('IS_S4H')
    PARAMETER-TABLE
      lt_params.
ELSE.
  lv_iss4 = abap_false.
ENDIF.

Answer 2

使用方法cl_cos_utilities=>is_s4h是一个相当不干净的解决方案，因为旧版本中不存在该方法。

更简洁的方法是使用函数模块SFW_IS_BFUNC_SWITCHED_ON。此功能模块检查switch框架中的业务功能是否启用。

要检查S4HANA on premise业务功能，请执行以下操作：

CALL FUNCTION 'SFW_IS_BFUNC_SWITCHED_ON'
  EXPORTING
    bfunc_name     = 'SIMPLIFY_ON_PREMISE'
  IMPORTING
    is_switched_on = is_s4.

要检查云上的S4HANA业务功能，请执行以下操作：

CALL FUNCTION 'SFW_IS_BFUNC_SWITCHED_ON'
  EXPORTING
    bfunc_name     = 'SIMPLIFY_PUBLIC_CLOUD'
  IMPORTING
    is_switched_on = is_s4.

顺便说一句：cl_cos_utilities=>is_s4h方法实际上在内部使用了这个函数模块。

您可能还想检查在您的用例中，使用该功能模块来实际检测哪些HR业务功能处于活动状态是否更合适，而不是从系统是否已启用S/4间接获取该信息。

Answer 3

有一个函数模块OCS_GET_INSTALLED_COMPS，它返回所有已安装的软件组件。请注意，它不是由SAP发布的。它曾经在旧系统中工作，现在仍然在S/4HANA中工作。