如何保存使用ttslib的处理草图生成的音频？

Question

我正在做一个使用rita和ttslib库生成语音的处理草图(rita用于生成马尔可夫文本链，而ttslib正在将文本转换为语音)。

我似乎不知道该怎么做，就是把那个演讲作为音频文件保存到我的电脑上。下面是我当前的代码：

import ddf.minim.*;
import rita.*;
import guru.ttslib.*;

Minim minim;
AudioOutput out;
AudioRecorder recorder;

TTS voice1, voice2, voice3;
RiMarkov rm;
String[] sourceTextArray, script;
String title, sourceText;
int targetScriptLength;

void setup() {
  noLoop();
  minim = new Minim(this);
  out = minim.getLineOut();
  recorder = minim.createRecorder(out, "recording.wav");
    System.setProperty("mbrola.base","C:\\Users\\kandr\\Desktop\\Dropbox\\Coding & Web Design\\Processing 3\\libraries\\mbrola\\");
}

void draw() {
  generateScript("https://en.wikipedia.org/wiki/Special:Random");
  prepareVoices();
  recorder.beginRecord();
  speakScript(script);
  recorder.endRecord();
  recorder.save();
}


void prepareVoices() {
  voice1 = new TTS("mbrola_us1");
  voice1.setPitch(180.0);
  voice1.setPitchRange(25.0);

  voice2 = new TTS("mbrola_us3");
  voice2.setPitch(120.0);
  voice2.setPitchRange(15.0);

  voice3 = new TTS("mbrola_us3");
  voice3.setPitch(0.0);
}


void generateScript(String sourceURL) {
  sourceTextArray = loadStrings(sourceURL);
  sourceText = join(sourceTextArray, " ");

  // find random article's title
  title = sourceText.substring(sourceText.indexOf("<h1 id=\"firstHeading\" class=\"firstHeading\" lang=\"en\">") + 53, sourceText.indexOf("</h1>"));
  title = title.replaceAll("<.*?>", "");

  // load the source text into our Markov generator
  rm = new RiMarkov(3);
  rm.loadText(sourceText);

  // set the target script size and instantiate an array to hold the lines
  targetScriptLength = 20;
  script = new String[targetScriptLength];

  // generate lines to populate the script 
  for (int l = 0; l < targetScriptLength; l++) {
    script[l] = rm.generateSentence();
  }
}


void speakScript(String[] scriptArr) {
  for (int s = 0; s < scriptArr.length; s+=2) {
    voice1.speak(scriptArr[s]);
    voice2.speak(scriptArr[s+1]);
  } 
}

正如您所看到的，我尝试使用Minim库的AudioRecorder类来录制我的草图正在输出的音频。然而，没有实际的音频被记录-我只是以一个空的wav文件结束。我还尝试将AudioRecorder对象的可录制信号源设置为AudioInput，但这只是录制了我笔记本电脑麦克风的声音。

我还查看了处理附带的Sound库，但没有看到一个适合在其中录制音频的类。

谁能给我指出正确的方向，弄清楚如何让我的草图录制通过ttslib生成的音频？

Answer 1

首先，即使您编辑了问题，您发布的代码仍然需要额外的文件，因此无法测试。

无论如何，问题似乎出在Minim的API中，所以音频路由需要在草图之外完成。因为您是在windows上工作，所以只需将录制设备更改为"Stereo Mix“即可。这会将系统的音频输出重新路由到输入端，因此可以通过minim进行录制。

下面是我使用ttslib example和minim recorder example改编的一个小草图，它记录了ttslib库生成的语音。如果音频从系统设置重新路由。

import ddf.minim.*;
import ddf.minim.ugens.*;

import guru.ttslib.*;

Minim minim;

TTS tts;

AudioInput in;
AudioRecorder recorder;
boolean recorded;

AudioOutput out;
FilePlayer player;

void setup()
{
  size(512, 200, P3D);
  tts = new TTS();
  minim = new Minim(this);
  in = minim.getLineIn();
  recorder = minim.createRecorder(in, "test.wav", true);
  out = minim.getLineOut( Minim.STEREO );
  textFont(createFont("Arial", 12));
}

void draw()
{
  background(0); 
  stroke(255);
  for(int i = 0; i < in.left.size()-1; i++)
  {
    line(i, 50 + in.left.get(i)*50, i+1, 50 + in.left.get(i+1)*50);
    line(i, 150 + in.right.get(i)*50, i+1, 150 + in.right.get(i+1)*50);
  }

  if ( recorder.isRecording() )
  {
    text("Now recording, press the r key to stop recording.", 5, 15);
  }
  else if ( !recorded )
  {
    text("Press the r key to start recording.", 5, 15);
  }
  else
  {
    text("Press the s key to save the recording to disk and play it back in the sketch.", 5, 15);
  }
}

void keyReleased()
{
  if ( !recorded && key == 'r' ) 
  {
    if ( recorder.isRecording() ) 
    {
      recorder.endRecord();
      recorded = true;
    }
    else 
    {
      recorder.beginRecord();
    }
  }
  if ( recorded && key == 's' )
  {
    if ( player != null )
    {
        player.unpatch( out );
        player.close();
    }
    player = new FilePlayer( recorder.save() );
    player.patch( out );
    player.play();
  }
}

void mousePressed() {
  tts.speak("Hi! This voice is being recorded");
}