perl排序数组:保留以#开头的项

Question

有没有办法修改任何以#开头的字符串被忽略的排序，也就是保留它的索引？

例如：

my @stooges = qw(
        Larry
        Curly
        Moe
        Iggy
    );

my @sorted_stooges = sort @stooges;

@sorted_stooges应该提供：

Curly
Iggy
Larry
Moe

现在，如果我将#添加到Curly

my @stooges = qw(
            Larry
            #Curly
            Moe
            Iggy
        );

my @sorted_stooges = sort @stooges;

我希望@sorted_stooges是：

Iggy
#Curly
Larry
Moe

Answer 1

就地解决方案：

my @indexes_to_sort = grep { $array[$_] !~ /^#/ } 0..$#array;
my @sorted_indexes = sort { $array[$a] cmp $array[$b] } @indexes_to_sort;
@array[@indexes_to_sort] = @array[@sorted_indexes];

或

my @indexes_to_sort = grep { $array[$_] !~ /^#/ } 0..$#array;
@array[@indexes_to_sort] = sort @array[@indexes_to_sort];

或

my $slice = sub { \@_ }->( grep { !/^#/ } @array );
@$slice[0..$#$slice] = sort @$slice;

(不幸的是，@$slice = sort @$slice;不起作用，-It替换了@$slice的元素，而不是赋值给它们-但找到了一个合适的替代方案。)

Answer 2

提取需要排序的元素，然后用排序后的元素更新原始数组：

my @stooges = qw( Larry #Curly Moe Iggy );
my @sorted_items = sort grep { not /^#/ } @stooges;
my @sorted_stooges = map { /^#/ ? $_ : shift @sorted_items } @stooges;
say for @sorted_stooges;

在他们的回答中，@ikegami提出了这种方法的一种变体，即提取要排序的元素的索引，而不是提取元素本身。该解决方案允许数组元素与列表切片进行优雅的交换。