什么是cfi_adjust_cfa_offset和cfi_rel_offset？

Question

我目前正在尝试理解glibc的syscall函数的内部代码。下面是代码(采用from here)。

/* In the EABI syscall interface, we don't need a special syscall to
   implement syscall().  It won't work reliably with 64-bit arguments
   (but that is true on many modern platforms).  */
ENTRY (syscall)
        mov        ip, sp
        push        {r4, r5, r6, r7}
        cfi_adjust_cfa_offset (16)
        cfi_rel_offset (r4, 0)
        cfi_rel_offset (r5, 4)
        cfi_rel_offset (r6, 8)
        cfi_rel_offset (r7, 12)
        mov        r7, r0
        mov        r0, r1
        mov        r1, r2
        mov        r2, r3
        ldmfd        ip, {r3, r4, r5, r6}
        swi        0x0
        pop        {r4, r5, r6, r7}
        cfi_adjust_cfa_offset (-16)
        cfi_restore (r4)
        cfi_restore (r5)
        cfi_restore (r6)
        cfi_restore (r7)
        cmn        r0, #4096
        it        cc
        RETINSTR(cc, lr)
        b        PLTJMP(syscall_error)
PSEUDO_END (syscall)

我对传递系统调用号和参数的代码有一定的了解，它们是syscall函数的核心函数。但是我不明白cfi_adjust_cfa_offset指令、cfi_rel_offset指令和cfi_restore指令是做什么的。我知道这些指令与syscall函数的功能没有多大关系。但是，我仍然想知道这些指令是做什么的。

谢谢。

Answer 1

这些不是指令，而是assembler directives (通常它们应该以.开头，但这里是they are macros，可能是为了处理汇编程序中的差异)。它们告诉汇编程序对特殊的元数据进行编码，这有助于调试器和异常处理程序正确地展开堆栈。通常它们是由编译器发出的，所以你不会经常看到它们，但它们在低级代码或像这里这样的手写汇编中特别重要。

让我们来看一下代码。首先，介绍一些背景知识。

CFA代表“规范帧地址”，默认情况下等于调用点的sp的值(see here)。在ARM调用中，不会将返回地址推送到堆栈上，因此函数入口的sp是相同的。

mov ip, sp

这会将CFA值(即sp，因此指向不适合r0-r3寄存器的任何附加参数)复制到ip(也称为r12)寄存器。

push {r4,r5,r6, r7}

这将保存即将修改但假定不会被调用修改的寄存器(非易失性寄存器)。推送将CFA值更改为4*4 =16字节，不再等于sp。

cfi_adjust_cfa_offset(16)

这将发出一个操作码，该操作码告诉调试器CFA位于距假定CFA (sp)的偏移量16处。

cfi_rel_offset(r4, 0)

这告诉调试器，可以在新调整后的r4的偏移量0处找到CFA值的原始值。下面的指令描述了其他三个已保存的寄存器。

    mov        r7, r0
    mov        r0, r1
    mov        r1, r2
    mov        r2, r3
    ldmfd        ip, {r3, r4, r5, r6}
    swi        0x0

这将以EABI调用约定期望的方式设置syscall参数( r7中的syscall编号，r0-r6中的第一个参数)，然后调用syscall指令

    pop        {r4, r5, r6, r7}
    cfi_adjust_cfa_offset (-16)
    cfi_restore (r4)
    cfi_restore (r5)
    cfi_restore (r6)
    cfi_restore (r7)

在这里，我们恢复以前保存的寄存器，将CFA调整回-16 (因为pop指令更改了sp，并指定寄存器已恢复为其原始值)。