如何引用Isar中的当前子目标？

Question

我正在尝试解决Programming and Proving in Isabelle中的练习4.7。我遇到了一个案例，在这个案例中，我证明了错误，因此证明了一切，但我不能结案，因为我不知道如何引用我的证明义务。

theory ProgProveEx47
  imports Main
begin

datatype alpha = a | b | c

inductive S :: "alpha list ⇒ bool" where
  Nil: "S []" |
  Grow: "S xs ⟹ S ([a]@xs@[b])" |
  Append: "S xs ⟹ S ys ⟹ S (xs@ys)"

fun balanced :: "nat ⇒ alpha list ⇒ bool" where
  "balanced 0 [] = True" |
  "balanced (Suc n) (b#xs) = balanced n xs" |
  "balanced n (a#xs) = balanced (Suc n) xs" |
  "balanced _ _ = False"

lemma
  fixes n xs
  assumes b: "balanced n xs"
  shows "S (replicate n a @ xs)"
proof -
  from b show ?thesis
  proof (induction xs)
    case Nil
    hence "S (replicate n a)"
    proof (induction n)
      case 0
      show ?case using S.Nil by simp
      case (Suc n)
      value ?case
      from `balanced (Suc n) []` have False by simp
      (* thus "S (replicate (Suc n) a)" by simp *)
      (* thus ?case by simp *)
      then show "⋀n. (balanced n [] ⟹ S (replicate n a)) ⟹ balanced (Suc n) [] ⟹ S (replicate (Suc n) a)" by simp

最后一个show之后的命题是从Isabelle/jedit中的证明状态复制过来的。但是，Isabelle报告了错误(在最后一个show)：

   Failed to refine any pending goal 
Local statement fails to refine any pending goal
Failed attempt to solve goal by exported rule:
  (balanced 0 []) ⟹
  (balanced ?na3 [] ⟹ S (replicate ?na3 a)) ⟹
  (balanced (Suc ?na3) []) ⟹
  (balanced ?n [] ⟹ S (replicate ?n a)) ⟹
  (balanced (Suc ?n) []) ⟹ S (replicate (Suc ?n) a)

现在注释掉的证明目标导致了同样的错误。如果我将案例替换为0和Suc，则错误出现在0案例的最后一个show中，但不再出现在Suc案例中。

有人能解释一下为什么伊莎贝尔不会接受这些看似正确的目标吗？我如何以Isabelle可以接受的方式陈述子目标？有没有引用当前子目标的一般方法？我认为考虑到我使用的构造，?case应该能完成这项工作，但很明显它不能。

我发现this堆栈溢出问题提到了相同的错误，但问题不同(定理存在等价性，应该通过rule的隐式应用将其拆分为方向子目标)，在我的情况下，应用所提供的解决方案会导致不正确和不可证明的目标。

Answer 1

你只是在内部归纳证明中遗漏了一个next。

lemma
  fixes n xs
  assumes b: "balanced n xs"
  shows "S (replicate n a @ xs)"
proof -
  from b show ?thesis
  proof (induction xs)
    case Nil
    hence "S (replicate n a)"
    proof (induction n)
      case 0
      show ?case using S.Nil by simp
    next (* this next was missing *)
      case (Suc n)
      show ?case sorry
    qed
    show ?case sorry
  next
    case (Cons a xs)
    then show ?case sorry
  qed