是否可以通过Terraform脚本创建WAFv2

Question

我设法使用Terraform脚本在亚马逊网络服务上构建了一个网站管家(V1)基础设施组件。自2019年11月以来，亚马逊网络服务建议使用WAFv2，但我不知道如何使用Terraform编写脚本。

Answer 1

terraform还不支持这一点。但是，如果你真的想使用terraform，我已经构建了一个使用cloudformation资源来部署wafv2的模块。你可以在-> https://github.com/umotif-public/terraform-aws-waf-webaclv2上找到它

它被发布到terraform注册表，因此您可以从那里获取它。

Answer 2

当然可以，下面是WAFv2的资源示例，其中包含速率限制示例规则以及与ALB的关联：

resource "aws_wafv2_web_acl" "my_web_acl" {
  name  = "my-web-acl"
  scope = "REGIONAL"

  default_action {
    allow {}
  }

  rule {
    name     = "RateLimit"
    priority = 1

    action {
      block {}
    }

    statement {

      rate_based_statement {
        aggregate_key_type = "IP"
        limit              = 500
      }
    }

    visibility_config {
      cloudwatch_metrics_enabled = true
      metric_name                = "RateLimit"
      sampled_requests_enabled   = true
    }
  }

  visibility_config {
    cloudwatch_metrics_enabled = false
    metric_name                = "my-web-acl"
    sampled_requests_enabled   = false
  }
}

resource "aws_wafv2_web_acl_association" "web_acl_association_my_lb" {
  resource_arn = aws_lb.my_lb.arn
  web_acl_arn  = aws_wafv2_web_acl.my_web_acl.arn
}