指标过滤器未分配给指标告警

Question

我正在使用terraform来设置aws cloudwatch日志，以便在日志中出现错误时发送电子邮件。

下面是terraform文件的外观：

resource "aws_cloudwatch_log_metric_filter" "error-importing-rfid-metric-filter" {
  name           = "rfid-data-import-metric-filter"
  log_group_name = var.SERVICE_NAME
  pattern        = "ERROR"
  metric_transformation {
    name      = "error-rfid-data-import"
    namespace = "DataImportErrorMetrics"
    value     = "1"
  }
}

resource "aws_cloudwatch_metric_alarm" "error-importing-rfid" {
  alarm_name          = "error-rfid-data-import"
  metric_name         = "DataImportErrorMetrics"
  threshold           = "0"
  statistic           = "Sum"
  comparison_operator = "GreaterThanThreshold"
  datapoints_to_alarm = "1"
  evaluation_periods  = "1"
  period              = "60"
  namespace           = "LogMetrics"

  alarm_actions = [aws_sns_topic.alarm.arn]
}

运行terrraform后，我可以看到过滤器已创建，警报也已创建。但是在alarm部分下，没有列出任何警报。你可以在图中看到，有两个过滤器，左边的过滤器列出了报警名称，右边的过滤器只显示无。左边的是在aws控制台上手动创建的，右边的是来自terraform的。实际上，在控制台上创建的那个就像是一个护身符，但右边的那个仍然处于数据不足状态

​

Answer 1

我解决了这个问题。指标名称实际上是指标转换名称。并且metric_tranformation中的命名空间必须与aws_cloudwatch_metric_alarm中的命名空间相同。正确的代码片段应该是

resource "aws_cloudwatch_log_metric_filter" "error-importing-rfid-metric-filter" {
  name           = "rfid-data-import-metric-filter"
  log_group_name = var.SERVICE_NAME
  pattern        = "ERROR"
  metric_transformation {
    name      = "error-rfid-data-import-metric"
    namespace = "LogMetrics"
    value     = "1"
  }
}

//set up the alarm
resource "aws_cloudwatch_metric_alarm" "error-importing-rfid" {
  alarm_name          = "error-rfid-data-import-alarm"
  metric_name         = "error-rfid-data-import-metric"
  threshold           = "0"
  statistic           = "Sum"
  comparison_operator = "GreaterThanThreshold"
  datapoints_to_alarm = "1"
  evaluation_periods  = "1"
  period              = "60"
  namespace           = "LogMetrics"

  alarm_actions = [aws_sns_topic.alarm.arn]
}