使用Spec验证已知和未知键值的映射

Question

我想创建一个clojure规范来验证由reitit.ring.middleware.multipart中间件创建的http请求的:multipart参数。

多部分表单数据必须包含可使用s/keys验证的特定参数，以及具有任意参数名称的任意数量的文件。

要验证的映射将如下所示：

           {:visualisation "vis"
            :file-xy       {:filename     "foo.png",
                            :content-type "image/png",
                            :tempfile     "C:\\Temp\\ring-multipart-123.tmp",
                            :size         295281}
            :file-abc      {:filename     "bar.png",
                            :content-type "image/png",
                            :tempfile     "C:\\Temp\\ring-multipart-456.tmp",
                            :size         42}}

我可以使用reitit.ring.middleware.multipart/temp-file-part规范验证文件，如下所示：

    (s/def :multipart/files (s/map-of :multipart/param multipart/temp-file-part))

综合起来，我提出了一个规范，它通过了，但它允许所有未知参数为文件或字符串：

(s/def :multipart/param keyword?)
(s/def :multipart/visualisation string?)
(s/def :multipart/items (s/map-of :multipart/param (s/or :file multipart/temp-file-part :visualisation string?)))
(s/def :visualisation/files (s/and (s/keys :req-un [:multipart/visualisation])
                                   :multipart/items))

如何为具有特定键的映射定义规范，并为其他键定义值验证器？

Answer 1

您可以添加一个谓词函数，以确保映射的值中只有一个是字符串：

(s/def :visualisation/files
  (s/and (s/keys :req-un [:multipart/visualisation])
         #(= 1 (count (filter string? (vals %))))
         :multipart/items))

(s/conform :visualisation/files
  {:visualisation "vis"
   :file-xy       {:filename "" :content-type "" :tempfile "" :size 0}})

(s/conform :visualisation/files
  {:visualisation "vis"
   :file-abc      "not valid"
   :file-xy       {:filename "" :content-type "" :tempfile "" :size 0}})

但是，如果您使用的是conform'd输出，那么通用的s/or规范将会产生冗余的标记。

另一种选择是使用两个规范检查：

(def data
  {:visualisation "vis"
   :file-xy       {:filename "" :content-type "" :tempfile "" :size 0}})

(s/conform (s/keys :req-un [:multipart/visualisation])
           data)

(s/conform (s/map-of :multipart/param :multipart/temp-file-part)
           (dissoc data :visualisation))

如果你可以控制数据的形状，或者可以重新排列它，我会考虑这样更容易规范的东西：

{:visualisation "foo"
 :files {:file-1 {,,,}
         :file-2 {,,,}}}