VB.NET中的FindWindowEx

Question

我有一个问题，如何使用FindWindowEx终止仅具有类名的进程

​

​

Answer 1

如果您能够可靠地从调用FindWindowEx中获得窗口句柄，则可以使用GetWindowThreadProcessId从窗口句柄中查找进程的ID。

一旦获得了进程ID，就可以通过该ID找到Process并对其调用Kill()。例如：

Imports System.Runtime.InteropServices
Imports System.Diagnostics

Module Module1

    <DllImport("user32.dll", SetLastError:=True)>
    Private Function GetWindowThreadProcessId(ByVal hwnd As IntPtr,
                          ByRef lpdwProcessId As Integer) As Integer
    End Function

    <DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Auto)>
    Private Function FindWindowEx(ByVal parentHandle As IntPtr,
                      ByVal childAfter As IntPtr,
                      ByVal lclassName As String,
                      ByVal windowTitle As String) As IntPtr
    End Function

    Sub Main()

        Dim hWnd As IntPtr = FindWindowEx(IntPtr.Zero, IntPtr.Zero, "Chrome_WidgetWin_0", "Spotify Premium")
        Dim ProcessId As Integer
        GetWindowThreadProcessId(hWnd, ProcessId)

        If ProcessId <> 0 Then
            Dim Process As Process = Process.GetProcessById(ProcessId)
            Process.Kill()
        End If


    End Sub

End Module

棘手的部分是确保你总是可以得到一个窗口句柄。考虑句柄有多个实例的情况。您提到了类名，但可能还需要向FindWindowEx提供窗口标题。

您可能还需要考虑如果调用Process.Kill()抛出异常会发生什么情况，例如，如果运行您的程序的用户没有权限终止该特定进程。