首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >从范围内填充ComboBox

问从范围内填充ComboBox
EN

Code Review用户
提问于 2016-09-10 06:36:50
回答 2查看 3.6K关注 0票数 3

最近,我有了很多有趣的回答堆栈溢出问题,我想我有点过火了,最后用一种相当不错的方式从Range中植入了一个ComboBox。

给定一个简单的UserForm,其中包含一些ComboBox1控件,我希望从Sheet1上的ListObject中填充这些控件,调用/客户端代码如下所示:

使用新UserForm1 .PopulateFromList .Show 1选择显式子测试()。(1).Show vbModal结束与End Sub

(感谢托马斯·因齐纳帮助处理列标题)

表单代码中的...the Change处理程序只是为了说明隐藏的ID列实际上被用作Combobox.Value:

代码语言:javascript
复制
Private Sub ComboBox1_Change()
    If Not IsNull(ComboBox1.Value) Then Debug.Print ComboBox1.Value, ComboBox1.Text
End Sub

而且起作用了!

代码语言:javascript
复制
 3            Star Wars
 1            Lord of the Rings

下面是表单的其余代码--后面,正在检查的实际代码--我想知道重用它的最佳方法是什么,我还没有决定是否最好将其作为一个实用工具提取到类模块中;有了WithEvents foo As ComboBox字段,我可以在那里拥有一个动态控件.但是,在某些随机形式的代码隐藏中,这显然是不实际的。

我对GetColumnWidths不太满意,我相信有更好的方法可以做到这一点。至于PopulateFromXxxx方法,.它们是完美的,不是吗?

代码语言:javascript
复制
Option Explicit

Public Sub PopulateFromList(ByVal source As ListObject, Optional ByVal valueColumn As Long = 1, Optional ByVal hasHeader As Boolean = True)
    With Me.ComboBox1
        .ColumnCount = source.Range.Columns.Count
        .ColumnWidths = GetColumnWidths(source.Range)
        .ListWidth = IIf(ComboBox1.Width > source.Range.Width, ComboBox1.Width, source.Range.Width)
        .RowSource = source.Name & "[#Data]"
        .BoundColumn = valueColumn
        .ColumnHeads = hasHeader
    End With
End Sub

Public Sub PopulateFromArray(ByVal source As Range, Optional ByVal valueColumn As Long = 1, Optional ByVal hasHeader As Boolean = True)
    With Me.ComboBox1
        .ColumnCount = source.Columns.Count
        .ColumnWidths = GetColumnWidths(source)
        .ListWidth = IIf(ComboBox1.Width > source.Width, ComboBox1.Width, source.Width)
        .List = source.Range(source.Rows(IIf(hasHeader, 2, 1)).EntireRow, source.Rows(source.Rows.Count).EntireRow).Value
        .BoundColumn = valueColumn
    End With
End Sub

Private Function GetColumnWidths(ByVal source As Range) As String
    Dim cols As Long
    cols = source.Columns.Count

    Dim widths()
    ReDim widths(1 To cols)
    Dim col As Long
    For col = 1 To cols
        widths(col) = source(, col).Width
    Next
    GetColumnWidths = Join(widths, ",")
End Function

有什么办法把这件事清理干净吗?.List在PopulateFromArray的任务似乎特别痛苦。

EN

回答 2

Code Review用户

发布于 2016-09-12 21:35:53

我不确定我会比较控件和范围的.width属性--听我说完。

让我们从一张相关测量表开始

代码语言:javascript
复制
Inch       .5
cm         1.27
Pixel      48
Point      36
Characters 5.38

具有范围

的

在excel UI中,当手动调整宽度时,您会看到两个数字--字符和像素。

字符是字体的字符数(我在这里使用默认的-杯标11),可以适应范围的宽度(是的,这是一个荒谬的测量单位)。

在范围的“格式”菜单中,列的宽度也是字符。

在VBA中

代码语言:javascript
复制
Range.Width = points (Variant Double)
Range.ColumnWidth = characters (Variant Double)

.width在这里给我们的点,然后必须除以.75,以获得像素匹配的UI。

具有表单

的

窗体上的active x组合框的属性为

代码语言:javascript
复制
ComboBox1.ColumnWidths = points (String)
ComboBox1.Width = pixels (Single)
ComboBox1.ListWidth = points (String)

代码中的

(

)

代码语言:javascript
复制
.ColumnWidths = GetColumnWidths(source.Range)
.ListWidth = IIf(ComboBox1.Width > source.Range.Width, ComboBox1.Width, source.Range.Width)

本质上,您可以用一个表示点的字符串来设置.ColumnWidths (以点数表示的字符串)。好的。

然后将像素与点进行比较,并将ListWidth (点中的字符串)设置为像素(作为单像素)或点(变体为双)。

这种混乱是无法避免的,所以我会提出另一个函数,返回一系列的点。

是的,这样做是不必要的复杂,除非有人试图调试更复杂的版本,或者你和我一样,而你讨厌excel这样做。

代码语言:javascript
复制
    Dim myControlBox As Control
    Set myControlBox = Me.ComboBox1
    With myControlBox
        .ColumnCount = source.Columns.Count
        .ColumnWidths = GetColumnWidths(source)
        .ListWidth = GetListWidth(source, myControlBox)
    End With

Private Function GetListWidth(ByVal source As Range, ByVal myControlBox As Control) As String
    If myControl.Width > source.Width Then
        GetListWidth = myControl.Width * 0.75
        Exit Function
    Else: GetListWidth = source.Width
End Function

这个答案花了我更长的时间来写我愿意承认的。

票数 3
EN

Code Review用户

发布于 2016-09-10 08:34:27

我搞错了专栏头像。当您使用RowSource时,它们会正确显示,而不是List。

我认为使用自定义类型来包装功能,确实可以清理代码。

Demo

码

代码语言:javascript
复制
Type ListSettings
    ColumnCount As Integer
    ColumnWidths As String
    ListWidth As String
    List As Variant
    RowSource As String
End Type

Function getListSettings(Source As Range, Optional ByVal hasHeader As Boolean = True) As ListSettings
    Dim r As Range
    Dim t As ListSettings
    Dim s As String

    For Each r In Source.Rows(1).Cells
        s = s & r.Width & ","
    Next
    'This works because Boolean Logic evaluates to -1 for True and 0 for False.
    Set Source = Source.Offset(Abs(hasHeader)).Resize(Source.Rows.Count + hasHeader)

    With t
        .ColumnCount = Source.Columns.Count
        .ColumnWidths = Left(s, Len(s) - 1)
        .ListWidth = Source.Width
        .List = Source
        .RowSource = Source.Address
    End With

    getListSettings = t
End Function

用户表单

代码语言:javascript
复制
Private Sub UserForm_Initialize()
    Dim t As ListSettings
    t = getListSettings(Sheet1.ListObjects(1).Range)

    With ListBox1
        .ColumnCount = t.ColumnCount
        .ColumnWidths = t.ColumnWidths
        .RowSource = t.RowSource
        .ColumnHeads = True
    End With

    With ListBox2
        .ColumnCount = t.ColumnCount
        .ColumnWidths = t.ColumnWidths
        .RowSource = t.RowSource
        .ColumnHeads = True
    End With

    With ComboBox1
        .ColumnCount = t.ColumnCount
        .ColumnWidths = t.ColumnWidths
        .List = t.List
        .ColumnHeads = True
        If .Width < t.ListWidth Then .ListWidth = t.ListWidth
    End With

    With ComboBox2
        .ColumnCount = t.ColumnCount
        .ColumnWidths = t.ColumnWidths
        .RowSource = t.RowSource
        .ColumnHeads = True
        .ListWidth = IIf(.ListWidth > t.ListWidth, .Width, t.ListWidth)
    End With

End Sub

Private Sub ComboBox2_DropButtonClick()
    ComboBox1.DropDown
End Sub
票数 2
EN
页面原文内容由Code Review提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://codereview.stackexchange.com/questions/140995

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档