可以将子字符串展开应用于zsh数组的所有元素吗？

Question

假设我想从数组的所有元素中删除前两个和最后三个字符。

results=( QK9H9UtADCgnG AlaLkCADjQ krsxseW8H1VrU 6nBG94ZbCWQ )

我想以

results=( 9H9UtADC aLkCA sxseW8H1 BG94Zb )

除了循环元素和使用${element:2:-3}之外，是否有一个标志或某种组合允许执行类似${(⭕)results:2:-3}的操作，从而使子字符串展开影响每个元素而不是影响数组？

如果重要的话，在我的特殊情况下，数组不能有空元素，元素不能包含任何类型的空白字符，提取规则总是L>P+S，即任何元素的_L_ength总是大于要删除的_S_uffix和_P_refix的合并长度。我对查询字符串和使用文本处理工具不感兴趣。正如我前面所说的，我目前正在使用一个函数来循环，所以这不是尝试输入更少的内容的问题，我只是好奇，在我浏览手册时，它是否有可能，并没有找到一个方法来实现它。

Answer 1

请注意，来自${string:offset:length}的ksh93并不是原生的zsh方式，它只是最近才添加的，是为了与ksh93 / bash兼容。

在zsh中，您更愿意使用$string[first,last] (它早于ksh93)。

但无论如何，无论是zsh的$var[first,last]还是ksh 93样式的${var:offset:length}，这些操作符都可以应用于字符串和数组(在zsh中，与bash/ksh相反，数组和标量是两种独立的变量类型，操作符可以在其中不同地应用)，在第一种情况下给出一个子字符串，在第二种情况下给出元素子集。

据我所知，您不能告诉zsh，这将应用于每个字符串元素，而不是整个数组。

${results[1][3,-4]} (或${results[1]:2:-3})可以工作，但是${results[1,2][3,-4]}不能产生数组，而不是字符串，所以[3,-4]按数组的方式应用。

然而，在这里，您可以采取不同的方法。

例如，可以将${string#pattern}和${string%pattern} ksh样式运算符应用于以下每个元素：

results=( ${${results#??}%???} )

或用于删除任意数目的前导字符和尾字符：

set -o extendedglob
results=( ${${results#?(#c5)}%?(#c8)} )

还可以使用ksh93 93样式的${array/pattern/replacement}对每个元素进行任意修改，例如：

set -o extendedglob
results=( ${results/(#m)*/$MATCH[3,-4]} )

另请参阅

results=( ${results/(#b)??(*)???/$match[1]} )

它只修改至少有5个字符的元素(与ksh93中的ksh93相同)。

另一种复杂的办法是：

() { results=( ${(e)argv} ); } '${results['{1..$#results}'][3,-4]}'

在其中，我们将${results[1][3,-4]}、${results[2][3,-4]}等传递给一个匿名函数，在该函数中，我们使用e标志对它们进行计算并将其分配回数组。

(在所有这些变量中，如果希望保留空元素，包括那些在修剪后变为空的元素，请使用带有[@]和引号的变体)。

Answer 2

下面是一种修剪数组元素的方法：

trimmed_array=( $(printf '%s\n' "${results[@]}" | cut -c 3- | rev | cut -c 4- | rev) )

检查新数组：

printf '%s\n' "${trimmed_array[@]}"
9H9UtADC
aLkCA
sxseW8H1
BG94Zb

每个管道段的动作都很容易检查和理解。