配置zsh以绿色显示我的stdin

Question

我想要一种简单的方法，用红色显示错误，在zsh中以绿色显示输入。我找到了这一反应，它工作得很好，但是它没有实现输入颜色。我不是一个真正的unix开发人员，所以我尝试了一些东西，但它不起作用。如何使用此方法或类似的方法将输入颜色更改为绿色？

下面是我的.zshrc中的实际内容：

setcolor()
{
    case "$1" in
    red)
        tput setaf 1
        ;;
    normal)
        tput sgr0
        ;;
    green)
        tput setaf 2
        ;;
    esac
}

# make standard error red
rederr()
{
    while read -r line
    do
        setcolor $errorcolor
        echo "$line"
        setcolor normal
    done
}

errorcolor=red

errfifo=${TMPDIR:-/tmp}/errfifo.$
mkfifo $errfifo
# to silence the line telling us what job number the background job is
exec 2>/dev/null
rederr <$errfifo&
errpid=$!
disown %+
exec 2>$errfifo

Answer 1

stdin是一个输入流，那里没有什么可以着色的。我假设您的意思是要将您在终端中键入的内容的回声涂成绿色，这要么是由内核中的终端设备驱动程序完成的，要么是由应用程序自己在实现自己的行编辑器时完成的。

如果您知道到终端的输出只会通过stdout、stderr或输入回显(由内核或实现自己的行编辑器并打开/dev/tty而不是使用stdout/stderr进行回波的应用程序)，那么您可以让stdout/stderr颜色器将输出的颜色更改为绿色，从而使非通过stdout或stderr输出的任何内容的默认颜色有效地变为绿色：

zmodload zsh/system
autoload colors; colors
colour-stream() {
  local buf output_colour=$fg[$1] after_colour=$fg[$2]
  while sysread buf; do
    syswrite -- $output_colour$buf$after_colour
  done > /dev/tty
}
exec 1> >(colour-stream default green) \
     2> >(colour-stream red     green)

通过直接打开$TTY或/dev/tty向终端写入的任何内容，如sudo密码提示或echo test > /dev/tty，也将显示为绿色。

一些shell(如bash )不会在stderr未到达终端时交互运行。您可以运行bash -i来绕过它，但是请注意，由于bash的readline输出了stderr上的输入回显，它将显示为红色。其他使用readline的应用程序(如gdb或python )可以使用stdout或stderr或open /dev/tty作为输入回波YMMV。对于TUI应用程序来说，情况可能会变得更糟。