利用谷歌单张中的SI单元

Question

七年前有人问这个问题，在SI单元的格式化方面有什么新的发展吗？

通常，我会通过除法将格式调整为所有milli或micro，但是我最近的概念证明将milli和micro的适用性混合在一起，这样数据集就跨越了milli和微边界。

在我的工程中，处理内燃机点火正时一直是一个不寻常的经历: RPM如何从大约900到14000不等，意味着要不断地了解数据类型的容量。

在这种情况下，有一个恢复时间，这是一个固定的值。它限制了这个系统的最大RPM，但它不能规定最大RPM，因为我正在测试的功能与恢复时间无关。盯着数字墙，很难掌握数值的大小并对数据进行解释。

样本数据集垂直排列。灰色是那些细胞中的方程式，绿色是我理想的格式。

RPM是不断变化的，占空比(也称为驻留)是可编程的。在本页中，我将验证观察到的时间，并试图将其与其他约束联系起来。

Answer 1

自定义数字格式支持条件，但其中只有两个加上默认格式。因此，要显示数以百万计的美元，可以使用Format > Number > More format> Custom ，如下所示：

[>999999999.999]$#.00,,, "B";[>999999.999]$#.00,, "M";$#,##0_M

不幸的是，只有当您的值包含几个数量级时，这才会看起来很漂亮。

要覆盖整个SI前缀范围，可以将值转换为另一个单元格或列中的文本，如下所示：

=arrayformula( 
  if( 
    isnumber(A2:A), 
    ifs( 
      abs(A2:A) >= 10^27, text(A2:A, "0.0##e+### "), 
      abs(A2:A) >= 10^24, text(A2:A / 10^24, "0.0## ""Y"""), 
      abs(A2:A) >= 10^21, text(A2:A / 10^21, "0.0## ""Z"""), 
      abs(A2:A) >= 10^18, text(A2:A / 10^18, "0.0## ""E"""), 
      abs(A2:A) >= 10^15, text(A2:A / 10^15, "0.0## ""P"""), 
      abs(A2:A) >= 10^12, text(A2:A / 10^12, "0.0## ""T"""), 
      abs(A2:A) >= 10^9, text(A2:A / 10^9, "0.0## ""G"""), 
      abs(A2:A) >= 10^6, text(A2:A / 10^6, "0.0## ""M"""), 
      abs(A2:A) >= 10^3, text(A2:A / 10^3, "0.0## ""k"""), 
      abs(A2:A) >= 10^2, text(A2:A / 10^2, "0.0## ""h"""), 
      abs(A2:A) >= 10^1, text(A2:A / 10^1, "0.0## ""da"""), 
      abs(A2:A) >= 10^0, text(A2:A / 10^0, "0.0## """""), 
      abs(A2:A) >= 10^(-1), text(A2:A / 10^(-1), "0.0## ""d"""), 
      abs(A2:A) >= 10^(-2), text(A2:A / 10^(-2), "0.0## ""c"""), 
      abs(A2:A) >= 10^(-3), text(A2:A / 10^(-3), "0.0## ""m"""), 
      abs(A2:A) >= 10^(-6), text(A2:A / 10^(-6), "0.0## ""µ"""), 
      abs(A2:A) >= 10^(-9), text(A2:A / 10^(-9), "0.0## ""n"""), 
      abs(A2:A) >= 10^(-12), text(A2:A / 10^(-12), "0.0## ""p"""), 
      abs(A2:A) >= 10^(-15), text(A2:A / 10^(-15), "0.0## ""f"""), 
      abs(A2:A) >= 10^(-18), text(A2:A / 10^(-18), "0.0## ""a"""), 
      abs(A2:A) >= 10^(-21), text(A2:A / 10^(-21), "0.0## ""z"""), 
      abs(A2:A) >= 10^(-24), text(A2:A / 10^(-24), "0.0## ""y"""), 
      true, text(A2:A, "0.0##e+### ") 
    ) 
    & 
    "g", 
    A2:A 
  ) 
)

公式应该转到空闲列的第2行。它以克表示重量。若要使用另一个单元，请将"g“替换为其他内容。

在1e±24的范围内，公式将使用科学的表示法。