DOMAIN_SEPARATOR in EIP712是什么？

Question

能否有人向我解释一下DOMAIN_SEPARATOR在EIP712中的使用，以及它如何确保同一用户在两个不同的Dapps中对相同的消息进行不同的签名？

Answer 1

这是每个域“混合”签名的唯一值。它使来自不同域的签名不兼容，因为它被设计为包含一些DApp唯一信息，例如DApp的名称、预期的验证器契约地址、预期的DApp域名等。

来源：https://eips.ethereum.org/EIPS/eip-712

Answer 2

有可能是两个DApps提出了一个相同的结构，如传输(地址，地址到，uint256数量)，不应该兼容。通过引入域分隔符，可以保证dApp开发人员不会出现签名冲突。

您可以看到Uniswap如何在ERC721Permit.sol中使用它的一个实际示例。

   function DOMAIN_SEPARATOR() public view override returns (bytes32) {
        return
            keccak256(
                abi.encode(
                    // keccak256('EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)')
                    0x8b73c3c69bb8fe3d512ecc4cf759cc79239f7b179b0ffacaa9a75d522b39400f,
                    nameHash,
                    versionHash,
                    ChainId.get(),
                    address(this)
                )
            );
    }

DOMAIN_SEPARATOR返回一个哈希值(bytes32)，这是在permit函数中使用的哈希值。

   function permit(
        address spender,
        uint256 tokenId,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external payable override {
        require(_blockTimestamp() <= deadline, 'Permit expired');
        // it is used to create another hash value to make it unique
        bytes32 digest = keccak256(
            abi.encodePacked(
                '\x19\x01',
                DOMAIN_SEPARATOR(),
                keccak256(abi.encode(PERMIT_TYPEHASH, spender, tokenId, _getAndIncrementNonce(tokenId), deadline))
            )
        );
        address owner = ownerOf(tokenId);
        require(spender != owner, 'ERC721Permit: approval to current owner');

        if (Address.isContract(owner)) {
            require(IERC1271(owner).isValidSignature(digest, abi.encodePacked(r, s, v)) == 0x1626ba7e, 'Unauthorized');
        } else {
            address recoveredAddress = ecrecover(digest, v, r, s);
            require(recoveredAddress != address(0), 'Invalid signature');
            require(recoveredAddress == owner, 'Unauthorized');
        }

        _approve(spender, tokenId);
    }