GradleCompatible新版本

Question

请你帮我解决这个问题，我不知道问题在哪里，我有所有的更新

问题：

所有com.android.support库都必须使用完全相同的版本规范(混合版本会导致运行时崩溃)。找到28.0.0，27.0.2版本。示例包括com.android.support:animated-vector-drawable:28.0.0和com.android.Support:定制选项卡:27.0.2减.(Ctrl+F1)检查信息:有一些库、工具和库的组合是不兼容的，或者可能导致错误。这种不兼容性之一是使用一个不是最新版本的Android支持库版本进行编译(特别是比您的targetSdkVersion低的版本)。发布id: GradleCompatible

apply plugin: 'com.android.application'

android {
    compileSdkVersion 28
    defaultConfig {
        applicationId "com.el.sohaib.babysitter"
        minSdkVersion 22
        targetSdkVersion 28
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    implementation 'com.android.support:appcompat-v7:28.0.0'

    implementation 'com.android.support:animated-vector-drawable:28.0.0'


    implementation 'com.android.support.constraint:constraint-layout:1.1.3'
    implementation 'com.facebook.android:facebook-android-sdk:[5,6)'
    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'com.android.support.test:runner:1.0.2'
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'
  //the erreur   implementation 'com.android.support:design:28.0.0'
}


apply plugin: 'com.android.application'

android {
    compileSdkVersion 28
    defaultConfig {
        applicationId "com.el.sohaib.babysitter"
        minSdkVersion 22
        targetSdkVersion 28
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation 'com.android.support:appcompat-v7:28.0.0'

    implementation 'com.android.support:animated-vector-drawable:28.0.0'


    implementation 'com.android.support.constraint:constraint-layout:1.1.3'
    implementation 'com.facebook.android:facebook-android-sdk:[5,6)'
    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'com.android.support.test:runner:1.0.2'
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'
    implementation 'com.android.support:design:28.0.0'
}

Answer 1

之所以显示此警告，是因为Facebook使用了支持库的旧版本。您在项目中使用的更新版本(28.0.0)并不顺利。

解决方案是排除在Facebook中使用的所有旧版本的库：

 implementation ('com.facebook.android:facebook-android-sdk:[5,6)') {
    exclude group: 'com.android.support', module: 'cardview-v7'
    exclude group: 'com.android.support', module: 'customtabs'
    exclude group: 'com.android.support', module: 'support-media-compat'
    exclude group: 'com.android.support', module: 'support-v4'
}

排除依赖项会导致运行时崩溃，因为库将调用那些排除在外的库中的函数。现在，您需要在依赖项中提供所有这些库的更新版本。

implementation 'com.android.support:cardview-v7:28.0.0'
implementation 'com.android.support:customtabs:28.0.0'
implementation 'com.android.support:support-media-compat:28.0.0'
implementation 'com.android.support:support-v4:28.0.0'

以下是我完整的build.gradle文件：

    apply plugin: 'com.android.application'

    apply plugin: 'kotlin-android'

    apply plugin: 'kotlin-android-extensions'

    android {
        compileSdkVersion 28
        defaultConfig {
            applicationId "com.example.myapplication"
            minSdkVersion 19
            targetSdkVersion 28
            versionCode 1
            versionName "1.0"
            testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        }
        buildTypes {
            release {
                minifyEnabled false
                proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            }
        }
    }

    dependencies {
        implementation fileTree(dir: 'libs', include: ['*.jar'])
        implementation"org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
        implementation 'com.android.support:appcompat-v7:28.0.0'
        implementation 'com.android.support.constraint:constraint-layout:1.1.3'

        /**
        * Providing newer versions of those libs
        */
        implementation 'com.android.support:cardview-v7:28.0.0'
        implementation 'com.android.support:customtabs:28.0.0'
        implementation 'com.android.support:support-media-compat:28.0.0'
        implementation 'com.android.support:support-v4:28.0.0'

        /**
        * Excluding older libs
        */
        implementation ('com.facebook.android:facebook-android-sdk:[5,6)') {
            exclude group: 'com.android.support', module: 'cardview-v7'
            exclude group: 'com.android.support', module: 'customtabs'
            exclude group: 'com.android.support', module: 'support-media-compat'
            exclude group: 'com.android.support', module: 'support-v4'
        }

        testImplementation 'junit:junit:4.12'
        androidTestImplementation 'com.android.support.test:runner:1.0.2'
        androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'


    }