如何将命令行本身打印到日志文件中以进行日志跟踪？

Question

我有一个通过.bat文件调用的java代码。这批货很好用。有没有办法将这个命令行打印到stdout (日志)文件中？

例如，我的命令是

call dpp.bat -r %BASE_URL% views -af xyz.csv >> creation.log 2>&1

在我的bat文件中，我有多种不同类型的此类命令。在执行这个单个批处理文件时，所有的事情都会一个接一个地执行，所有的日志都被写入到该单个文件creation.log中。而用户看不见日志，哪个命令行执行了什么！

有没有一种简单的方法，比如添加一些将命令行也打印到日志文件中的行？

Answer 1

实际上非常简单，只需将echo %* --这将打印出在命令行中传递的参数。

Answer 2

如果我正确理解，您希望将命令回显和命令输出都写入日志文件。

要实现这一点，您可以执行以下操作：

• 将要登录到子例程中的代码放在call调用的子例程中。
• 重定向只将call命令输出到日志文件。
• 将@echo off放入批处理文件的主部分。
• 将@echo on放入子例程中.
• 不要忘记将exit /B放在主部分的末尾。

下面是一个示例：

@rem // Turn command echoes off in the main section:
@echo off
@rem // Redirect only the output of `call` to the log file:
call :SUB >> "creation.log" 2>&1
@rem // Terminate main section:
@exit /B

:SUB
    @rem // Turn command echoes on in the sub-section:
    @echo on
    @rem /* Place all command lines you want to log here;
    @rem    ensure NOT to precede these lines with `@`: */
    call dpp -r %BASE_URL% views -af xyz.csv
    @rem // Terminate sub-section:
    @exit /B

或者，您可以将每个命令放入一个只迭代一次的循环播放中：

@rem // Turn command echoes on:
@echo on
@rem // Place all command lines you want to log into `for` loops that iterate once:
@(for %%# in (.) do call dpp -r %BASE_URL% views -af xyz.csv) > "creation.log" 2>&1
@rem // Terminate script:
@exit /B