如何在linux中加快awk命令的速度？

Question

我在linux中使用awk命令将utc转换为本地时间，但是文件大小很大(>30 gb)，花费超过一个小时。

这是我的代码：

awk -F"," '{cmd="date -d \"$(date -d \""$1"\")-4hours\" \"+%Y%m%d_%H\"";cmd | getline datum; close(cmd); print $0 ","datum""}' data.txt

我如何加快这个命令的速度，或者在linux中有什么简单的方法来完成这个转换呢？

Here is the sample of input:

utc,id
2018-03-31 16:00:49.425,4485
2018-04-1 17:01:19.425,30019
2018-05-31 18:01:49.425,15427
2018-08-20 19:01:55.425,17579
2018-09-2 20:02:31.425,23716
2018-10-15 21:03:34.425,24772

expected output:

utc,id,localtime
2018-03-31 16:00:49.425,4485,20180331_12
2018-04-1 17:01:19.425,30019,20180401_13
2018-05-31 18:01:49.425,15427,20180531_14
2018-08-20 19:01:55.425,17579,20180820_15
2018-09-2 20:02:31.425,23716,20180902_16
2018-10-15 21:03:34.425,24772,20181015_17

Answer 1

您的原始解决方案之所以缓慢，是因为系统调用date。使用awk处理的每条记录/行都调用一个外部命令来执行日期转换。这样的外部调用需要加载到内存中，执行，其输出需要由awk处理。如果我们能够在awk本身中完成实际的数据转换，我们就可以加快速度。

的一般性评论:当您将日期和时间从UTC转换到您的本地时区时，您必须考虑到1月1日的时区与8月1日不同，这是由于夏令时。下面的算法没有提供这样的解决方案，因为OP只是请求4小时的移位，或者是转移到他当前的时区。(注: gawk 4.1.2或更高版本的解决方案将考虑DST )

下面我介绍几种解决方案，您可以根据使用哪个awk使用这些解决方案：

Gnu awk:是gawk的一种扩展，它是时间函数.解决这个问题的两个有用的时间函数是mktime和strftime。

• mktime(datespec,[utc-flag])：--它将表单YYYY MM DD hh mm ss的日期规范字符串datespec转换为Unix时代时间，即自1970 01 UTC以来的总秒数。由于gawk-4.2.1，您可以使用utc-flag来指示datespec是否在UTC。在gawk-4.2.1之前，它假定了当地的时区.
• strftime(format,timestamp,[utc-flag])：将划时代的timestamp转换为格式化的字符串(与date命令的格式相同)。您可以使用utc-flag，指示返回的时间应该在UTC或本地时区。

GNU awk手册中的更多信息

我们希望将字段1从UTC转换为本地时区。由于我们不知道字段1的格式，我们假设存在一个函数convert_time(str)，它将str格式化为mktime可以接受的格式YYYY MM DD hh mm ss。

gawk 4.1.2或更高版本：

$ awk 'BEGIN{FS=OFS=","}
      { # convert $1 into YYYY MM DD hh mm ss
        datestring=convert_time($1)
        # convert datestring (as UTC) into epoch 
        datum=mktime(datestring,1)
        # convert epoch into string (local TZ)
        datum=strftime("\042%Y%m%d_%H\042",datum)
        # print and append
        print $0,datum
      }' data.txt

在gawk 4.1.2之前:这里我们不能使用utc-flag，所以我们强迫awk在协调时工作：

$ TZ=UTC awk 'BEGIN{FS=OFS=","}
             { # convert $1 into YYYY MM DD hh mm ss
               datestring=convert_time($1)
               # convert datestring (as UTC) into epoch 
               datum=mktime(datestring)
               # perform TZ correction
               datum-=4*3600;
               # convert epoch into string (local TZ)
               datum=strftime("\042%Y%m%d_%H\042",datum)
               # print and append
               print $0,datum
              }' data.txt

POSIX：--如果您没有GNU，但是没有任何其他awk，则不能使用这些时间函数，因为它们是GNU特定的。然而，有可能执行这些原则：

awk '

# Algorithm from "Astronomical Algorithms" By J.Meeus
function mktime_posix(datestring,    a,t) {
    split(datestring,a," ")
    if (a[1] < 1970) return -1
    if (a[2] <= 2) { a[1]--; a[2]+=12 }
    t=int(a[1]/100); t=2-t+int(t/4)
    t=int(365.25*a[1]) + int(30.6001*(a[2]+1)) + a[3] + t - 719593
    return t*86400 + a[4]*3600 + a[5]*60 + a[6]
}

function strftime_posix(epoch, JD,yyyy,mm,dd,HH,MM,SS,A,B,C,D,E ) {
    if (epoch < 0 ) return "0000 00 00 00 00 00.000000"
    JD=epoch; SS=JD%60; JD-=SS; JD/=60; MM=JD%60;
    JD-=MM; JD/=60; HH=JD%24; JD-=HH; JD/=24;
    JD+=2440588
    A=int((JD - 1867216.25)/(36524.25))
    A=JD+1+A-int(A/4)
    B=A+1524; C=int((B-122.1)/365.25); D=int(365.25*C); E=int((B-D)/30.6001)
    dd=B-D-int(30.6001*E)
    mm = E < 14 ? E-1 : E - 13
    yyyy=mm>2?C-4716:C-4715
    return sprintf("\042%0.4d-%0.2d-%0.2d %0.2d:%0.2d:%06.3f",yyyy,mm,dd,HH,MM,SS)
}

{ # convert $1 into YYYY MM DD hh mm ss
  datestring=convert_time($1)
  # convert datestring (as UTC) into epoch 
  datum=mktime_posix(datestring)
  # perform TZ correction
  datum-=4*3600;
  # convert epoch into string (local TZ)
  datum=strftime_posix(datum)
  # print and append
  print $0,datum
}' data.txt