在安装使用NSIS开发的软件时，如果安装在服务器操作系统中，应该如何抛出弹出消息。

Question

在安装使用NSIS开发的软件时，如果在服务器操作系统中安装，我应该如何抛出弹出消息。

下面是不受支持的操作系统。在安装软件时，我应该显示弹出消息。

Windows Server 2003 
Windows Server 2003 R2
Windows Server 2008
Windows Server 2008 R2 
Windows Server 2012 
Windows Server 2012 R2

要实现这一点，我正面临困难。有谁能给我指点一下吗？

Answer 1

您可以使用WinVer.nsh来检测Windows版本

!include "LogicLib.nsh"    
!include "WinVer.nsh"

Function .onInit
    ${If} ${IsServerOS}
        MessageBox MB_OK "Running on Windows Server."
        Quit
    ${EndIf}
FunctionEnd

如果您需要更具体的，您可以结合在AtLeastWin* / AtMostWin*，其中*是您的目标版本(例如AtLeastWin2003 / AtLeastWin2012R2)

Answer 2

使用WinVer.nsh检测Windows版本：

!include WinVer.nsh
!include LogicLib.nsh
!define /IfNDef ERROR_INSTALL_REJECTED 1654

Function .onInit
${If} ${IsServerOS}
    ${If} ${AtLeastWin2003}
    ${AndIf} ${AtMostWin2012R2}
        MessageBox mb_IconStop|mb_OK "Not allowed to run on this version of Windows for some reason!" /SD IDOK
        SetErrorLevel ${ERROR_INSTALL_REJECTED}
        Quit
    ${EndIf}
${EndIf}
FunctionEnd

请记住，这不会阻止NT4和2000的服务器版本，也不会阻止服务器2016。如果要阻止所有服务器版本，则只需要进行${IsServerOS}检查。