避免Haskell中的重复实例声明

Question

我的问题似乎与这 one密切相关。

我的代码解析一个yaml文件，备份对象并编写一个新的yaml文件。它运行得很好，但其中有一个特别丑陋的部分。

我必须将数据结构声明为FromJson和ToJson的实例，如下所示：

instance FromJSON Users where
  parseJSON = genericParseJSON (defaultOptions { fieldLabelModifier = body_noprefix })
instance ToJSON Users where
  toJSON = genericToJSON (defaultOptions { fieldLabelModifier = body_noprefix })

问题是，我必须在大约8宗其他个案中重复这点：

instance FromJSON Role where
  parseJSON = genericParseJSON (defaultOptions { fieldLabelModifier = body_noprefix })
instance ToJSON Role where
  toJSON = genericToJSON (defaultOptions { fieldLabelModifier = body_noprefix })

...
...

我想不出如何避免这种重复。有什么方法只声明这两个函数一次(例如在一个新的类中)并让所有这些数据类型从它派生出来吗？

解决方案(另见dfeuer接受的答案)：

我个人喜欢这个解决方案。你需要添加

{-# language DerivingVia #-}
{-# language UndecidableInstances #-}

newtype NP a = NP {unNP::a} 

instance (Generic a, GFromJSON Zero (Rep a)) => FromJSON (NP a) where
  parseJSON = fmap NP . genericParseJSON 
    (defaultOptions { fieldLabelModifier = body_noprefix })

instance (Generic a, GToJSON Zero (Rep a)) => ToJSON (NP a) where
  toJSON = genericToJSON (defaultOptions { fieldLabelModifier = body_noprefix }) . unNP

然后，您可以这样声明类型：

data User = User { ... } deriving (Show, Generic)
                         deriving FromJSON via (NP User)
                         deriving ToJSON via (NP User)

Answer 1

这就是非常新的DerivingVia扩展的目的，除其他外。

{-# language DerivingVia #-}

newtype NP a = NP {unNP::a}

instance (Generic a, GFromJSON Zero (Rep a)) => FromJSON (NP a) where
  parseJSON = fmap NP . genericParseJSON 
    (defaultOptions { fieldLabelModifier = body_noprefix })

instance (Generic a, GToJSON Zero (Rep a)) => ToJSON (NP a) where
  toJSON = genericToJSON (defaultOptions { fieldLabelModifier = body_noprefix }) . unNP

现在，你可以写

deriving via (NP User) instance FromJSON User

或

data User = ...
  deriving Generic
  deriving (FromJSON, ToJSON) via (NP User)

诸若此类。

这并没有为左撇子的回答省多少钱。但是，一旦添加了toEncoding的定义，它就开始看起来很有价值了。

警告:我没有测试过这一切。

Answer 2

喜欢,

noPrefixParseJSON :: (Generic a, GFromJSON Zero (Rep a)) => Value -> Parser a
noPrefixParseJSON
    = genericParseJSON (defaultOptions { fieldLabelModifier = body_noprefix })
noPrefixToJSON :: (Generic a, GToJSON Zero (Rep a)) => a -> Value
noPrefixToJSON
    = genericToJSON (defaultOptions { fieldLabelModifier = body_noprefix })

instance FromJSON User where parseJSON = noPrefixParseJSON
instance ToJSON User where toJSON = noPrefixToJSON
instance FromJSON Role where parseJSON = noPrefixParseJSON
instance ToJSON Role where toJSON = noPrefixToJSON
...

当然，这仍然是重复的，但我想说，这不再是任何担心的原因。

Answer 3

如果显式声明所有类似的实例证明过于繁琐，也许可以使用类似的幻影型来参数化数据类型

data User x = User { aa :: Int, bb :: Bool } deriving Generic

data Role x = Role { xx :: Int, dd :: Bool } deriving Generic

然后定义一个“标记”数据类型，如

data Marker

此数据类型将仅用作挂起实例的挂钩，如下所示

{-# language UndecidableInstances #-}
instance (Generic (f Marker), GFromJSON Zero (Rep (f Marker))) => FromJSON (f Marker) where 
    parseJSON = noPrefixParseJSON

值得吗？可能不会，因为数据类型的定义变得更加复杂。另一方面，您可以通过更改标记来更改序列化的各个方面，从而获得一些灵活性。