从数据创建规范

Question

我正试图仅仅根据数据创建规范。我有非常复杂的数据结构-所有嵌套的地图。

{:contexts
 ({:importer.datamodel/global-id "01b4e69f86e5dd1d816e91da27edc08e",
   :importer.datamodel/type "province",
   :name "a1",
   :importer.datamodel/part-of "8cda1baed04b668a167d4ca28e3cef36"}
  {:importer.datamodel/global-id "8cda1baed04b668a167d4ca28e3cef36",
   :importer.datamodel/type "country",
   :name "AAA"}
  {:importer.datamodel/global-id "c78e5478e19f2d7c1b02088e53e8d8a4",
   :importer.datamodel/type "location",
   :importer.datamodel/center ["36." "2."],
   :importer.datamodel/part-of "01b4e69f86e5dd1d816e91da27edc08e"}
  {:importer.datamodel/global-id "88844f94f79c75acfcb957bb41386149",
   :importer.datamodel/type "organisation",
   :name "C"}
  {:importer.datamodel/global-id "102e96468e5d13058ab85c734aa4a949",
   :importer.datamodel/type "organisation",
   :name "A"}),
 :datasources
 ({:importer.datamodel/global-id "Source;ACLED",
   :name "ACLED",
   :url "https://www.acleddata.com"}),
 :iois
 ({:importer.datamodel/global-id "item-set;ACLED",
   :importer.datamodel/type "event",
   :datasource "Source;ACLED",
   :features
   ({:importer.datamodel/global-id
     "c74257292f584502f9be02c98829d9fda532a492e7dd41e06c31bbccc76a7ba0",
     :date "1997-01-04",
     :fulltext
     {:importer.datamodel/global-id "df5c7d6d075df3a7719ebdd39c6d4c7f",
      :text "bla"},
     :location-meanings
     ({:importer.datamodel/global-id
       "e5611219971164a15f06e07228fb7b51",
       :location "8cda1baed04b668a167d4ca28e3cef36",
       :contexts (),
       :importer.datamodel/type "position"}
      {:importer.datamodel/global-id
       "af36461d27ec1d8d28fd7f4a70ab7ce2",
       :location "c78e5478e19f2d7c1b02088e53e8d8a4",
       :contexts (),
       :importer.datamodel/type "position"}),
     :interaction-name "Violence",
     :importer.datamodel/type "description",
     :has-contexts
     ({:context "102e96468e5d13058ab85c734aa4a949",
       :context-association-type "actor",
       :context-association-name "actor-1",
       :priority "none"}
      {:context "88844f94f79c75acfcb957bb41386149",
       :context-association-type "actor",
       :context-association-name "actor-2",
       :priority "none"}),
     :facts
     ({:importer.datamodel/global-id
       "c46802ce6dcf33ca02ce113ffd9a855e",
       :importer.datamodel/type "integer",
       :name "fatalities",
       :value "16"}),
     :attributes
     ({:name "description",
       :importer.datamodel/type "string",
       :value "Violence"})}),
   :attributes (),
   :ioi-slice "per-item"})}

什么样的工具可以为这样的结构创建规范？我正在尝试使用这个工具：https://github.com/stathissideris/spec-provider

但它给了我这个：

(spec/def :importer.datamodel/data
  (clojure.spec.alpha/coll-of
   (clojure.spec.alpha/or
    :collection
    (clojure.spec.alpha/coll-of
     (clojure.spec.alpha/keys
      :req
      [:importer.datamodel/global-id]
      :opt
      [:importer.datamodel/center
       :importer.datamodel/part-of
       :importer.datamodel/type]
      :opt-un
      [:importer.datamodel/attributes
       :importer.datamodel/datasource
       :importer.datamodel/features
       :importer.datamodel/ioi-slice
       :importer.datamodel/name
       :importer.datamodel/url]))
    :simple
    clojure.core/keyword?)))

这不是一个完整的解决方案。我用(sp/pprint-specs (sp/infer-specs data :importer.datamodel/data) 'data 's)..。什么样的工具可以为这样的结构创建规范？

Answer 1

我正在尝试使用这个工具：https://github.com/stathissideris/spec-provider

规范提供程序没有给出所需的结果，因为您的数据是一个复杂的嵌套/递归结构。其中一些映射最好使用多规格进行说明，但规范提供者不会这样做；文档中的一个警告说，并没有试图推断多规格.。

正确规范其中一些映射的唯一方法是使用多规格，它们的规范将取决于它们的:importer.datamodel/type值。

首先，让我们看一下顶级键(假设映射位于名为data的绑定中)：

(keys data) => (:contexts :datasources :iois)

为最外层的地图创建一个s/keys规范：

(s/def ::my-map
  (s/keys :req-un [::contexts ::datasources ::iois]))

这些键是不合格的，但是我们必须使用限定关键字w/:req-un来规范它们。通过遍历嵌套结构并收集数据，我们可以使用REPL查看嵌套映射的形状及其与:importer.datamodel/type的关系：

(let [keysets (atom #{})]
  (clojure.walk/postwalk
    (fn [v]
      (when (map? v)
        (swap! keysets conj [(:importer.datamodel/type v) (keys v)]))
      v)
    data)
  @keysets)
=>
#{...
  ["organisation" (:importer.datamodel/global-id :importer.datamodel/type :name)]
  [nil (:context :context-association-type :context-association-name :priority)]
  ["description"
   (:importer.datamodel/global-id :date :fulltext :location-meanings
    :interaction-name :importer.datamodel/type :has-contexts :facts :attributes)]
  ["event" (:importer.datamodel/global-id :importer.datamodel/type :datasource :features :attributes :ioi-slice)]
 ...}

(即将出现的规范alpha将使从这些数据以编程方式定义规范变得更容易。)

多规格

我们可以看到有一些地图形状没有:importer.datamodel/type，但我们可以为那些有多个规格。首先，定义一个用于对类型键进行调度的多重方法：

(defmulti type-spec :importer.datamodel/type)

然后为每个defmethod值编写一个:importer.datamodel/type。以下是几个例子：

(defmethod type-spec :default [_] (s/keys))
(defmethod type-spec "organisation" [_]
  (s/keys :req [:importer.datamodel/global-id]
          :req-un [::name]))
(defmethod type-spec "description" [_]
  (s/keys :req [:importer.datamodel/global-id]
          :req-un [::date ::fulltext ::location-meanings ::interaction-name
                   ::has-contexts ::facts ::attributes]))
(defmethod type-spec "event" [_]
  (s/keys :req-un [::features]))

然后定义s/multi-spec

(s/def ::datamodel
  (s/multi-spec type-spec :importer.datamodel/type))

现在，我们遵循的任何映射都将根据::datamodel的:importer.datamodel/type值解析一个规范。我们可以将该规范分配给规范将用于匹配映射的关键字，例如最外层的键之一：

(s/def ::contexts (s/coll-of ::datamodel))

现在，如果您从我们在:contexts下指定的映射中移除所需的密钥，规范可以告诉您出了什么问题。例如，从:name映射中移除"organisation"键：

(s/explain ::my-map data)
In: [:contexts 3]
val: #:importer.datamodel{:global-id "88844f94f79c75acfcb957bb41386149",
                          :type "organisation"}
fails spec: :playground.so/datamodel
at: [:contexts "organisation"]
predicate: (contains? % :name)

其他规格

对于没有:importer.datamodel/type的映射，您应该能够定义键规范。例如，嵌套的:has-contexts键有一个没有:importer.datamodel/type的映射集合，但是如果我们可以假设它们都是相似的，那么我们可以编写这个规范：

(s/def ::has-contexts
  (s/coll-of (s/keys :req-un [::context ::context-association-type
                              ::context-association-name ::priority])))

:has-contexts在我们已经用上面的多个规范讨论过的地图中，只要在这个键上注册一个规范就可以使spec符合它的值。包含此规范的最外层键是:iois，因此我们也可以指定该键：

(s/def ::iois (s/coll-of ::datamodel))

现在，符合::my-map规范的输入将自动覆盖更多的数据。

什么样的工具可以为这样的结构创建规范？

正如您所看到的，为这个结构编写一个完整的规范并不简单，但却是可能的。我不知道有任何现有的工具能够自动推断出这个结构的完整的、“正确的”规范。它将不得不直觉，:importer.datamodel/type是一个关键，可以用来分派到不同的s/keys规范-它仍然是一个潜在的无效假设。在这种情况下，我认为工具辅助的规范生成更加现实和实用。

Answer 2

为什么不使用触发器创建一个历史表，该触发器在事务之前插入旧数据。

就像这样，

CREATE TRIGGER SNAPSHOT_TRIGGER BEFORE
INSERT ON MY_TABLE REFERENCING NEW ROW MYNEWROW
FOR EACH ROW
BEGIN
 INSERT INTO "HISTORY_TABLE" VALUES(121,'','zzzz');
END;

(请检查语法)

Answer 3

使用HANA2SPS 03，您可以使用系统版本表特性。对于系统版本表，HANA自动保存一个独立的旧记录版本表，这些旧记录版本可以独立于主表访问。