使用XSLT将多个输出的XML转换为具有单个输出的XML
使用XSLT将多个输出的XML转换为具有单个输出的XML
提问于 2019-01-28 12:58:54
我试图使用XSLT将具有多个输出的(平面) XML转换为具有单个输出的XML。但是必须对每个节点重复的节点却被忽略了。XML文件有两个输出:头部和实验。
源XML文档：
<?xml version="1.0" encoding="utf-8"?>
<ELEMENT>
<HEAD>
<FIRSTNAME>Anton</FIRSTNAME>
<SURNAME>Konchik</SURNAME>
<REPORTDATE>01.01.2019</REPORTDATE>
</HEAD>
<EXPERIMENT>
<NAME>EXPERIMENT1</NAME>
<DATE>01.01.2018</DATE>
<RESULT>POSITIVE</RESULT>
</EXPERIMENT>
<EXPERIMENT>
<NAME>EXPERIMENT2</NAME>
<DATE>01.01.2019</DATE>
<RESULT>NEGATIVE</RESULT>
</EXPERIMENT>
<EXPERIMENT>
<NAME>EXPERIMENT3</NAME>
<DATE>01.01.2017</DATE>
<RESULT>NOTSURE</RESULT>
</EXPERIMENT>
</ELEMENT>通过使用下面的代码，我希望在每个实验节点中复制头节点。XSLT转换代码：
<?xml version='1.0' ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" version="2.0" encoding="UTF-8" />
<xsl:template match="/">
<xsl:element name="ELEMENT">
<xsl:for-each select="ELEMENT/EXPERIMENT">
<xsl:element name="EXPERIMENT">
<xsl:element name="NAME">
<xsl:value-of select="./NAME"/>
</xsl:element>
<xsl:element name="DATE">
<xsl:value-of select="./DATE"/>
</xsl:element>
<xsl:element name="RESULT">
<xsl:value-of select="./RESULT"/>
</xsl:element>
<xsl:for-each select="ELEMENT/HEAD">
<xsl:element name="FIRSTNAME">
<xsl:value-of select="./FIRSTNAME"/>
</xsl:element>
<xsl:element name="SURNAME">
<xsl:value-of select="./SURNAME"/>
</xsl:element>
<xsl:element name="REPORTDATE">
<xsl:value-of select="./REPORTDATE"/>
</xsl:element>
</xsl:for-each>
</xsl:element>
</xsl:for-each>
</xsl:element>
</xsl:template>
</xsl:stylesheet>例外结果：
<?xml version="1.0" encoding="utf-8"?>
<ELEMENT>
<EXPERIMENT>
<NAME>EXPERIMENT1</NAME>
<DATE>01.01.2018</DATE>
<RESULT>POSITIVE</RESULT>
<FIRSTNAME>Anton</FIRSTNAME>
<SURNAME>Konchik</SURNAME>
<REPORTDATE>01.01.2019</REPORTDATE>
</EXPERIMENT>
<EXPERIMENT>
<NAME>EXPERIMENT2</NAME>
<DATE>01.01.2019</DATE>
<RESULT>NEGATIVE</RESULT>
<FIRSTNAME>Anton</FIRSTNAME>
<SURNAME>Konchik</SURNAME>
<REPORTDATE>01.01.2019</REPORTDATE>
</EXPERIMENT>
<EXPERIMENT>
<NAME>EXPERIMENT3</NAME>
<DATE>01.01.2017</DATE>
<RESULT>NOTSURE</RESULT>
<FIRSTNAME>Anton</FIRSTNAME>
<SURNAME>Konchik</SURNAME>
<REPORTDATE>01.01.2019</REPORTDATE>
</EXPERIMENT>
</ELEMENT>但是头节点被忽略了。实际结果：
<?xml version="1.0" encoding="utf-8"?>
<ELEMENT>
<EXPERIMENT>
<NAME>EXPERIMENT1</NAME>
<DATE>01.01.2018</DATE>
<RESULT>POSITIVE</RESULT>
</EXPERIMENT>
<EXPERIMENT>
<NAME>EXPERIMENT2</NAME>
<DATE>01.01.2019</DATE>
<RESULT>NEGATIVE</RESULT>
</EXPERIMENT>
<EXPERIMENT>
<NAME>EXPERIMENT3</NAME>
<DATE>01.01.2017</DATE>
<RESULT>NOTSURE</RESULT>
</EXPERIMENT>
</ELEMENT>谢谢你的帮助。
回答 1
Stack Overflow用户
回答已采纳
发布于 2019-01-28 13:20:00
更改：
<xsl:for-each select="ELEMENT/HEAD">至：
<xsl:for-each select="/ELEMENT/HEAD">或者：
<xsl:for-each select="../HEAD">您要寻找的是ELEMENT，它是当前EXPERIMENT的一个子级。您需要的是从树的根开始，或者在层次结构中向上。
还请注意，您可以简单地这样做：
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/ELEMENT">
<xsl:copy>
<xsl:for-each select="EXPERIMENT">
<xsl:copy>
<xsl:copy-of select="*"/>
<xsl:copy-of select="../HEAD/*"/>
</xsl:copy>
</xsl:for-each>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/54402562
复制相关文章
相似问题
腾讯云开发者
Copyright © 2013 - 2026 Tencent Cloud. All Rights Reserved. 腾讯云 版权所有
深圳市腾讯计算机系统有限公司 ICP备案/许可证号：粤B2-20090059 
粤公网安备44030502008569号
腾讯云计算（北京）有限责任公司 京ICP证150476号 | 京ICP备11018762号