使用Mysql或PowerBI和3个表(数据集)，如何将工作日添加到销售日期？

Question

我在Mysql服务器和PowerBI中有以下表(其中任何一种解决方案都有效)。

销售表

Date sold | Product | item | address
24-11-2018 | socks | 02 | orlando 
26-11-2018 | socks | 02 | mexico df

日历表

Date | isWeekend | isHoliday | isWorkday
24-11-2018 | 1 |  0 | 0
25-11-2018 | 1 |  1 | 0
26-11-2018 | 0 |  0 | 1
27-11-2018 | 0 |  0 | 1

按地点分列的天数表

address | days to deliver in workdays
orlando |  4

我需要在“销售表”中添加一个新列，其中我得到了“交付日期”，即“销售日期”+“交付日期”之和。现在，我遇到的问题是，我无法/不知道如何才能只增加工作日。

Answer 1

我将过滤Calendar表，添加一个运行/累积工作日列，然后将该days to deliver值匹配到正确的累积行。

Date to Deliver =
VAR Dates = FILTER ( 'Calendar', 'Calendar'[Date] > Sales[Date sold] )
VAR CumDays =
    ADDCOLUMNS (
        Dates,
        "CumWorkdays", CALCULATE (
            SUM ( 'Calendar'[isWorkday] ),
            FILTER ( Dates, 'Calendar'[Date] <= EARLIER ( [Date] ) )
        )
    )
VAR DaysToDeliver =
    LOOKUPVALUE (
        DaysToDeliverByLocation[days to deliver in workdays],
        DaysToDeliverByLocation[address], Sales[address]
    )
RETURN
    MINX ( FILTER ( CumDays, [CumWorkdays] = DaysToDeliver ), [Date] )