首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >带有esttab/estout的LaTeX表的跨多色统计量

问带有esttab/estout的LaTeX表的跨多色统计量
EN

Stack Overflow用户
提问于 2018-11-07 18:03:58
回答 1查看 1.1K关注 0票数 1

我希望在使用esttab时能够将统计数据集中在多个列上。

在我的玩具示例中,我希望N跨越两列:

代码语言:javascript
复制
sysuse auto, clear

est clear
qui estpost sum if foreign == 1
qui est store sum_foreign
qui estpost sum
qui est store sum_all

esttab sum_foreign sum_all, ///
    replace ///
    cells("mean(fmt(3)) sd(fmt(3))") ///
    nonum ///
    collabels("Mean" "SD") ///
    label ///
    noobs ///
    drop(make) ///
    stats(N, ///
        fmt(%9.0fc) ///
        label("Observations"))

虽然这个玩具示例只使用Stata的输出,但总的来说,我想在LaTeX中这样做。

表的其他部分(collabels、mgroups等)您可以指定pattern()参数,这允许您跨越,但这不是stats()的选项。

有人知道我怎样才能计算模型的宽度(2列)的观测值吗?

EN

回答 1

Stack Overflow用户

回答已采纳

发布于 2018-11-07 18:41:37

您需要使用适当的estadd标记作为前缀,在每个统计数据之间手动插入所需的间隔。为了正确排版表,这是必要的。

以下几点对我来说是可行的:

代码语言:javascript
复制
sysuse auto, clear

est clear
estpost sum if foreign == 1

local N1 \hspace{1.2cm}`e(N)'
estadd local NA `N1'

est store sum_foreign
estpost sum

local N2 \hspace{2cm}`e(N)'
estadd local NA `N2'

est store sum_all

esttab sum_foreign sum_all using table.tex, ///
    replace ///
    cells("mean(fmt(3)) sd(fmt(3))") ///
    nonum ///
    collabels("Mean" "SD") ///
    label ///
    noobs ///
    drop(make) ///
    stats(NA, ///
        fmt(%9.0fc) ///
        label("Observations"))

编辑:

这是另一种方法,但使用的是观察数字的自动对中:

代码语言:javascript
复制
sysuse auto, clear

est clear
estpost sum if foreign == 1

local N1 &\multicolumn{2}{c}{`e(N)'}

estadd local NA `N1'
est store sum_foreign

estpost sum

local N2 &\multicolumn{2}{c}{`e(N)'}

estadd local NA `N2'
est store sum_all

esttab sum_foreign sum_all using table.tex, ///
    replace ///
    cells("mean(fmt(3)) sd(fmt(3))") ///
    nonum ///
    collabels("Mean" "SD") ///
    label ///
    noobs ///
    drop(make) /// 
    postfoot("\hline Observations: `N1' `N2' \\ \hline\hline \\ \end{tabular} \\ }")
票数 1
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/53195216

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档