如何用test.check生成随机图？

Question

为了生成测试，我试图以邻接列表的形式生成一个随机图。一个例子图是：

{:a #{:a :b}, :b #{:a :b}}

(邻接列表以集的形式实现。)

我的第一个想法是：

(def vertex-gen (tcgen/fmap (comp keyword str) tcgen/char-alpha-numeric))

(def random-graph-gen-1
  (tcgen/let [vertices (tcgen/set vertex-gen {:min-elements 1})]
             (tcgen/map (tcgen/elements vertices)
                        (tcgen/set (tcgen/elements vertices)))))

(之所以需要{min-elements 1}，是因为tcgen/elements不适用于空集。)

但是，这样做可能会生成图，例如

{:a #{:a :b}}

其中，:b是随机为:a的邻接列表选择的，而不是为图本身选择的，因此:a有一个不存在的邻域。

另一个选择是

(def random-graph-gen-2
  (tcgen/let [vertices (tcgen/set vertex-gen)]
             (->> vertices
                  (map #(->> vertices
                             (tcgen/elements)
                             (tcgen/set)
                             (tcgen/generate)
                             (vector %)))
                  (into {}))))

它遍历所有顶点并显式地为每个顶点生成一个随机邻接列表。这保证了所有的顶点都会出现在图中，但缺点是test.check没有看到生成的邻接列表。所以我担心这会破坏缩小的逻辑。

是否有一种解决方案可以避免这两种缺陷？

Answer 1

另一种方法是：

(def graph-gen
  (gen/let [vertices (gen/set vertex-gen {:min-elements 1})
            edges (-> vertices
                      (gen/elements)
                      (gen/set)
                      (gen/vector (count vertices)))]
    (zipmap vertices edges)))

这引入了第二个生成器，它为每个顶点生成一组边，然后将顶点和边压缩到一个映射中。

在第二个例子中使用generate将引入不受整个生成器大小约束的随机性。来自generate docstring：

请注意，此函数是一个dev助手，不打算用于构建其他生成器。

但是您可以使用generate从不同大小的生成器中进行采样：

(gen/generate graph-gen 2)
=> {:F #{}, :e #{}, :S #{:e}}
(gen/generate graph-gen 10)
=>
{:L #{:n :7 :8 :H},
 :n #{:L :n :7 :C :8 :b :H :V},
 :7 #{:L :7 :C :8 :9 :b},
 :C #{:L :9 :V},
 :8 #{:L :n :7 :C :8 :9 :b :V},
 :9 #{:L :b :a},
 :b #{:n :V},
 :H #{:a},
 :V #{:n :C :b :H},
 :a #{}}