如何使用FireDAC提取存储过程DDL

Question

我正处于从FIBPlus到FireDAC的转换过程中，我需要的大多数功能都是在FireDAC中，我只是在努力寻找FIBPlus等效的TpFIBDBSchemaExtract和TpFIBScripter来将存储过程提取为DDL。

FireDAC有从数据库中提取存储过程DDL的方法吗？

例如，如下所示：

SET TERM ^ ;

CREATE PROCEDURE MY_PROC RETURNS (aParam INTEGER) AS
BEGIN
  aParam = 10;
END^

Answer 1

FireDAC不支持(统一)获取存储过程的DDL定义(此时)。因此，您需要自己从RDB$PROCEDURE_SOURCE列的RDB$PROCEDURES表中获取DDL。例如(但不是理想的设计为连接对象助手)：

uses
  FireDAC.Stan.Util;

type
  TFDConnectionHelper = class helper for TFDConnection
  public
    function GetStoredProcCode(const AName: string): string;
  end;

implementation

{ TFDConnectionHelper }

function TFDConnectionHelper.GetStoredProcCode(const AName: string): string;
var
  Table: TFDDatSTable;
  Command: IFDPhysCommand;
begin
  CheckActive;
  if RDBMSKind <> TFDRDBMSKinds.Firebird then
    raise ENotSupportedException.Create('This feature is supported only for Firebird');

  Result := '';
  ConnectionIntf.CreateCommand(Command);

  Command.CommandText := 'SELECT RDB$PROCEDURE_SOURCE FROM RDB$PROCEDURES WHERE RDB$PROCEDURE_NAME = :Name';
  Command.Params[0].DataType := ftString;
  Command.Params[0].Size := 31;
  Command.Params[0].AsString := UpperCase(AName);

  Table := TFDDatSTable.Create;
  try
    Command.Define(Table);
    Command.Open;
    Command.Fetch(Table);

    if Table.Rows.Count > 0 then
      Result := Table.Rows[0].GetData(0);
  finally
    FDFree(Table);
  end;
end;

然后使用(当您连接到Firebird DBMS时)：

procedure TForm1.Button1Click(Sender: TObject);
var
  S: string;
begin
  S := FDConnection1.GetStoredProcCode('MyProcedure');
  ...
end;