在Delphi中，TBitmap.Monochrome和.PixelFormat是如何影响.ScanLine格式的？

Question

我希望为位图分配一个具有Mono8格式(单色8位)位图的给定缓冲区。然后，我将结果位图分配给一个TImage组件来显示它。这些图片是结果显示的屏幕截图。

以下代码工作正常，但似乎有点浪费：

procedure CopyToBitmapMono824(_Buffer: PByte; _Bmp: TBitmap);
var
  y: Integer;
  x: Integer;
  ScanLine: PdzRgbTripleArray;
begin
  for y := 0 to _Bmp.Height - 1 do begin
    ScanLine := _Bmp.ScanLine[y];
    for x := 0 to _Bmp.Width - 1 do begin
      // monochrome: all 3 colors set to the same value
      ScanLine[x].Red := _Buffer^;
      ScanLine[x].Green := _Buffer^;
      ScanLine[x].Blue := _Buffer^;
      Inc(_Buffer);
    end;
  end;
end;

// [...]
fBmp.PixelFormat := pf24Bit;
FBmp.Monochrome := False;
CopyToBitmap(Buffer, fBmp);

​

​

我宁愿使用pf8Bit格式的位图，我试过这样做：

procedure CopyToBitmapMono8(_Buffer: PByte; _Bmp: TBitmap);
var
  y: Integer;
  x: Integer;
  ScanLine: PByteArray;
begin
  for y := 0 to _Bmp.Height - 1 do begin
    ScanLine := _Bmp.ScanLine[y];
    for x := 0 to _Bmp.Width - 1 do begin
      ScanLine[x] := _Buffer^;
      Inc(_Buffer);
    end;
  end;
end;

// [...]
FBmp.PixelFormat := pf8bit;
FBmp.Monochrome := False; // I also tried Monochrome := true
CopyToBitmapMono8(Buffer, FBmp)

如果MonoChrome为真，则图片只有预期宽度的1/4左右，其余为白色。

​

​

如果monochrome是假的，则图片具有预期的宽度，但左边的1/4是单色，其余的则包含假颜色。

​

​

我显然遗漏了什么，但是什么？

编辑:位图仅为预期大小的1/4，这显然是将其转换为JPEG以在显示之前保存的副作用(我上面没有显示的代码，意味着过失)。所以问题很简单，我没有为位图设置单色调色板。

Answer 1

Monochrome对pf1bit位图有意义。

否则，Monochrome := True将位图格式更改为DDB (pfDevice)。您的屏幕是32位，所以对Scanline的调用导致DibNeeded调用并转换为32位，而使用函数CopyToBitmapMono8 (用于8位)只填充了屏幕的1/4。

为了正确使用8位位图，您必须将标准的怪异调色板(在上一张图像的右侧)更改为灰色调色板。

procedure CopyToBitmapMono8(_Buffer: PByte; _Bmp: TBitmap);
var
  y: Integer;
  x: Integer;
  ScanLine: PByteArray;
begin
  for y := 0 to _Bmp.Height - 1 do begin
    ScanLine := _Bmp.ScanLine[y];
    for x := 0 to _Bmp.Width - 1 do begin
      ScanLine[x] := _Buffer^;
      Inc(_Buffer);
    end;
  end;
end;

var
   FBmp: TBitmap;
   Buffer: PbyteArray;
   i: integer;
begin
  GetMem(Buffer, 512 * 100);
  for i := 0 to 512 * 100 - 1 do
     Buffer[i] := (i and 511) div 2; // gray gradient

  FBmp := Tbitmap.Create;
  FBmp.Width := 512;
  FBmp.Height := 100;
  FBmp.PixelFormat := pf8bit;
  CopyToBitmapMono8(PByte(Buffer), FBmp);
  Canvas.Draw(0, 0, FBmp);

  //now right approach
  FBmp.Palette := MakeGrayPalette; // try to comment
  CopyToBitmapMono8(PByte(Buffer), FBmp);
  Canvas.Draw(0, 110, FBmp);

end;

function TForm1.MakeGrayPalette: HPalette;
var
  i: integer;
  lp:  TMaxLogPalette;
begin
  lp.palVersion    := $300;
  lp.palNumEntries := 256;
  for i := 0 TO 255 do begin
     lp.palPalEntry[i].peRed   := i;
     lp.palPalEntry[i].peGreen := i;
     lp.palPalEntry[i].peBlue  := i;
     lp.palPalEntry[i].peFlags := PC_RESERVED;
   end;
   Result := CreatePalette(pLogPalette(@lp)^);
end;

​

​

以及efg2页面上的示例