bash和awk脚本以YYYY-MM-DD格式到达前一个月的日期

Question

我需要得到上个月的日期在YYYY DD格式，假设如果运行脚本在五月在任何日期，那么它应该返回我的最后一个四月的日期2018-04-30格式。

Would be good if can get the same work done with awk statement also.

我尝试了下面的代码，并能够以下面的形式获得输出，但我需要格式为。

Apr 30 2018

代码：

#!/bin/bash
cur_month=`date +%m`
cur_year=`date +%Y`
prev_month=$(($cur_month-1))

# Check to see if this is January
if [ $prev_month -lt 1 ]
then
prev_year=$(($cur_year-1))
prev_month=12
LastDayOfpreviousMonth=`cal $prev_month $cur_year | grep -v "^$" | sed -n  '1p;$p' | tr "\n" " "  | awk '{print substr($1,1,3),$NF,$2}'`
else
LastDayOfpreviousMonth=`cal $prev_month $cur_year | grep -v "^$" | sed -n  '1p;$p' | tr "\n" " "  | awk '{print substr($1,1,3),$NF,$2}'`
fi
echo $LastDayOfpreviousMonth

输入文件:在column14文件中，需要将上个月的日期值以YYYY DD(2018-04-30)的形式列出。

EPOS|EPOS_OUTWARD_B2B_OSR_TTML_TTSL_$LDPM_20180504_V1.0.txt|||AD|Outward|ANP|Receipt cum invoice|42018|37AAACT2438A1ZS|INV|TAX|IN37201800001452|2018-04-17||||1||||SOHANRAJ RAJ KUMAR||||37||||||9984||Telecommunication services||||300|0||9|27|9|27|||||354||||||||||
EPOS|EPOS_OUTWARD_B2B_OSR_TTML_TTSL_$LDPM_20180504_V1.0.txt|||AD|Outward|ANP|Receipt cum invoice|42018|37AAACT2438A1ZS|INV|TAX|IN37201800001426|2018-04-12||||1||||MOLLITE SIVARAMA KRISHNA||||37||||||9984||Telecommunication services||||300|0||9|27|9|27|||||354||||||||||
EPOS|EPOS_OUTWARD_B2B_OSR_TTML_TTSL_$LDPM_20180504_V1.0.txt|||GJ|Outward|GUJ|Receipt cum invoice|42018|24AAACT2438A1ZZ|INV|TAX|IN24201800000651|2018-04-07||||1||||AIREN LTD ||||24||||||9984||Telecommunication services||||500|0||9|45|9|45|||||590||||||||||

Answer 1

尽管OP的日期格式显然是基于unix的，但值得一提的是，有两种通用日历在发挥作用。朱利安历法和公历。这两种日历对闰年有不同的概念。

注：此时，大多数国家采用公历。然而，并非所有国家都立即正式通过了该决议。在进行历史研究时，应该牢记这一点。例如，在英国，这一变化最早发生在公元1752年，而在土耳其则不是在1927年之前。(参考天文演算法)

考虑到这一点，并根据您的数字文件是来自土耳其从1920年还是2011年，还是大不列颠从1740年或1789年，我提出了两个awk解决方案

在闰年，二月有29天，而在普通年份有28天。

在朱利安历法中，如果一个年份的数值可以除以4，则它是一个闰年(或称双六分年)，所有其他年份都是普通年份(365天)。

使用awk，因为这是OP的请求，我们可以编写以下函数来执行请求的转换：

awk 'function julian(str,    y,m,d) {
         y=substr(str,1,4); m=substr(str,6,2)+0;
         if (m==1) {y=y-1; m=12} else {m=m-1}
         if (((m-1)%7)%2==0) {d=31} else {d=30}
         if (m==2) { d = (y%4==0) ? 29 : 28 }
         return sprintf("%0.4d-%0.2d-%0.2d",y,m,d)
      }
      { print $14, julian($14) }' <file>

在公历中，除了以下例外，同样的规则也适用于儒略历:不能被400整除的百岁是常见的年份。

awk 'function gregorian(str,    y,m,d) {
         y=substr(str,1,4); m=substr(str,6,2)+0;
         if (m==1) {y=y-1; m=12} else {m=m-1}
         if (((m-1)%7)%2==0) {d=31} else {d=30}
         if (m==2) { d = (y%4!=0) ? 28 : (y%100==0 && y%400!=0 ?  28 : 29 ) }
         return sprintf("%0.4d-%0.2d-%0.2d",y,m,d)
      }
      { print $14, gregorian($14) }' <file>

由于UNIX日历是Gregorian，所以我们也可以使用GNU Awk时间函数。然而，这只在1970-02-01至2038-01-19期间才适用于32位系统，292277026596-04-01适用于64位系统(请参阅这里)。

awk 'function unix(str,    tmp) {
        tmp=substr(str,1,7)" 01 00 00 00"; gsub("-"," ",tmp);
        return strftime("%Y-%m-%d",mktime(tmp) - 1) }
     { print $14, unix($14) }' <file>

Answer 2

GNU date本身能够完美、可靠地处理此任务，不需要其他魔术。

$ date -d "$(date +%Y-%m-01) - 1 day" "+%Y-%m-%d"
2018-04-30