首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >不包括周末的周转时间

问不包括周末的周转时间
EN

Stack Overflow用户
提问于 2018-04-17 06:47:57
回答 2查看 2K关注 0票数 0

嗨,不包括周末,我需要这个专栏的周转时间。我试着减去它,但没有排除周末,所以我没有成功地获得正确的周转时间所需。请帮助我得到正确的公式排除这个样本的周末。谢谢

​

您可以在这里看到,这是我需要的数据,以获得周转时间,所以我所做的是将N列减去M列。

​

这是我用正确的格式看到结果的公式,但是我想要一个结果,它不包括周末,但我不知道怎么做。

EN

回答 2

Stack Overflow用户

回答已采纳

发布于 2018-04-18 09:37:23

由于旧答案中的评论越来越多--以至于需要编辑来包含所有的“附加”要求(还有various reason,为什么这些chameleon questions经常会被反对)。对于更多的“调整”,提出一个新的问题。)-我在这里张贴更新的代码。

第一:由于NETWORKDAYS从第一天开始到最后一天结束都很重要,所以它倾向于增加“额外”一天。要解决这个问题,我们需要记住减去第一天的第一部分(午夜开始时间)和最后一天的最后一部分(结束时间到午夜),但前提是它们是每个工作日。

代码语言:javascript
复制
=NETWORKDAYS(M2,N2)+IF(MOD(WEEKDAY(N2),7)>1,MOD(N2,1)-1,0)-IF(MOD(WEEKDAY(M2),7)>1,MOD(M2,1),0)

其次是不包括假日的要求。重要!这要求您有一个名为“假日工作表”的工作表,并在A栏中列出您的假期日期。

我们使用ISERROR(MATCH(..))作为“不在列表中”的检查,NETWORKDAYS接受第三个可选的参数/参数

代码语言:javascript
复制
=NETWORKDAYS(M2,N2,'Holiday Sheet'!$A:$A)+IF(AND(MOD(WEEKDAY(N2),7)>1,ISERROR(MATCH(N2,'Holiday Sheet'!$A:$A,0))),MOD(N2,1)-1,0)-IF(AND(MOD(WEEKDAY(M2),7)>1,ISERROR(MATCH(M2,'Holiday Sheet'!$A:$A,0))),MOD(M2,1),0)

最后一个“额外”要求是将其计算为工作时间,工作日从07:00到16:00 --每天9小时。首先,将NETWORKDAYS乘以9小时(TIME(9,0,0)),然后记住删除第一天的第一部分(工作时间更正)和最后一天的最后一部分(也是工作时间的更正)。

我们可以使用MEDIAN从3个值中获取中间数,这样就不会在07:00之前或16:00之后使用时间。

代码语言:javascript
复制
=TIME(9,0,0)*NETWORKDAYS(M2,N2,'Holiday Sheet'!$A:$A)+IF(AND(MOD(WEEKDAY(N2),7)>1,ISERROR(MATCH(N2,'Holiday Sheet'!$A:$A,0))),MEDIAN(TIME(7,0,0),MOD(N2,1),TIME(16,0,0))-TIME(16,0,0),0)-IF(AND(MOD(WEEKDAY(M2),7)>1,ISERROR(MATCH(N2,'Holiday Sheet'!$A:$A,0))),MEDIAN(TIME(7,0,0),MOD(M2,1),TIME(16,0,0))-TIME(7,0,0),0)
票数 1
EN

Stack Overflow用户

发布于 2018-04-17 08:12:45

使用以下公式如何,这将计算两个日期之间的工作日:

代码语言:javascript
复制
=NETWORKDAYS(N2,M2)
票数 4
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/49871567

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档