在Haskell，如何组合最多n次的解析器？

Question

我试图组合Haskell中的解析器，这样我就可以解析某些模式，最多可以解析n次。为了举例说明，假设我想从输入中解析多达8位数字。我知道我可以使用count来解析Text.Parser.Combinators中的n个事件，例如：

import Text.Parser.Char        (digit)
import Text.Parser.Combinators (count)

eightDigits :: Parser [Char]
eightDigits = count 8 digit

但是，如果找不到确切的8位数字，这就失败了。我还可以使用some解析一个或多个数字：

import Text.Parser.Char        (digit)
import Text.Parser.Combinators (some)

someDigits :: Parser [Char]
someDigits = some digit

上面的问题是，它可能消耗比我想要的更多的数字。最后，我可以使用try，它结合了可能消耗输入的解析器，并在失败时返回到它开始的位置：

import Text.Parser.Char        (digit)
import Text.Parser.Combinators (count, try)
import Control.Applicative     ((<|>))

twoOrThreeDigits :: Parser [Char]
twoOrThreeDigits = try (count 3 digit) <|> count 2 digit

虽然这可以扩展到最多8个重复，但它既不可伸缩，也不优雅，所以问题是我如何组合解析器来解析1到n次之间的模式？

Answer 1

您可以构造具有上限的many-like组合器：

upto :: Int -> Parser a -> Parser [a]
upto n p | n > 0 = (:) <$> try p <*> upto (n-1) p <|> return []
upto _ _ = return []

对于1到n，一个many1-like组合器：

upto1 :: Int -> Parser a -> Parser [a]
upto1 n p | n > 0 = (:) <$> p <*> upto (n-1) p
upto1 _ _ = return []

一个简短的演示：

> map (parse (upto 8 digitChar) "") ["", "123", "1234567890"]
[Right "",Right "123",Right "12345678"]