TwinCAT 3:写入文件

Question

我想从我的PLC导出一些数据，将其写入文本文件并保存到USB卡中。我设法创建了文本文件，但是我什么也写不出来。

我在以下代码中使用来自TwinCAT标准库的函数：

PROGRAM P_WriteFile
VAR
    nStateP         :   INT :=  1;
    fbOpenFile      :   FB_FileOpen;    // open or create file
    fbWriteFile     :   FB_FilePuts;    // write to file
    fbCloseFile     :   FB_FileClose;   // Close file

    sPath           :   STRING  :=  '\Hard Disk2\foobar.txt';    // target path
    sAmsNetID       :   STRING  := '1.23.34.456.1.1';
    sOutput         :   STRING  :=  'foo';

    bDone           :   BOOL;
END_VAR

CASE nStateP OF
1:
// open/create file
    fbOpenFile(sNetId := sAmsNetID, sPathName := sPath, nMode := 2, bExecute := TRUE, tTimeout := INT_TO_TIME(200), bBusy =>, bError => , nErrId =>, hFile => );
    IF fbOpenFile.bBusy THEN
        nStateP :=  2;
    END_IF
2:
    // write to file
    IF NOT fbOpenFile.bError THEN
        fbWriteFile(sNetId := sAmsNetID, hFile := fbOpenFile.hFile, sLine := sOutput, bExecute := TRUE, tTimeout := INT_TO_TIME(200), bBusy =>, bError =>, nErrId =>);
        fbOpenFile(bExecute := FALSE);
    END_IF  
    IF fbWriteFile.bBusy THEN
        nStateP :=  3;
    END_IF

3:
    // Close file
    IF NOT fbWriteFile.bBusy AND NOT fbWriteFile.bError THEN
        fbCloseFile(sNetId := sAmsNetID, hFile := fbOpenFile.hFile, bExecute := TRUE, tTimeout := INT_TO_TIME(200), bBusy =>, bError =>, nErrId =>);
    END_IF

    IF fbWriteFile.bBusy THEN
        nStateP :=  4;
    END_IF

4:
    IF NOT fbCloseFile.bBusy AND NOT fbCloseFile.bError THEN
        bDone   :=  TRUE;
        nStateP :=  1;
    ELSE
        bDone   :=  FALSE;
    END_IF
END_CASE

程序进入所有状态，但结果是一个空文本文件，我无法在控制面板上打开该文件。(“访问\Hard Disk2\foobar.txt时发生了共享冲突”)

此外，函数的bBusy -变量(例如，FB_FileOpen.bBusy)不会更改回'FALSE‘。

如果有人能帮我，那就太好了！谢谢:)

Answer 1

通常:繁忙标志告诉您的是，函数块当前正忙着执行您请求FB执行的操作。这意味着，当状态机处于繁忙状态时，不应该更改状态机的状态，相反，应该改变状态机的状态。您还应该在下一步之前检查操作是否成功(通过查看bError-标志)。只要调用的函数块很忙(bBusy = true)，就可以调用函数块，并将bExecute标志设置为low。我通常所做的是将其设置为两个独立的开放阶段，例如：

某种伪代码：

Step1_Open:
  FBOPENFILE(bExecute=TRUE)...
   GOTO STEP2_OPEN

Step2_Open:
  FBOPENFILE(bExecute=FALSE)
  IF NOT FBOPENFILE.bBusy AND NOT FBOPENFILE.bError THEN
     GOTO Step3_StartWrite
  END_IF

Step3_StartWrite
  FBWRITEFILE(bExecute=TRUE)
  GOTO STEP4_WRITEFILE

Step4_Writefile:
  FBWRITEFILEFILE(bExecute=FALSE)
  IF NOT FBWRITEFILEFILE.bBusy AND NOT FBWRITEFILEFILE.bError THEN
     NEXT STEP
  END_IF

...and等等..。

所以在你的例子中，你的第二阶段非常关键。在写入完成之前，您不应该关闭该文件，一旦bBusy为false，就会关闭该文件。基本上，你要做的是在文件还在写的时候关闭它！另外，您可以在这个阶段删除"fbOpenFile(bExecute := FALSE)“，因为一旦您打开了文件并拥有一个文件句柄，您就不需要再调用这个函数块了。

其他想法：

sAmsNetId是您计算机中的本地计算机吗？如果是本地的，我不认为你需要提供。

我已经写了我自己的文件作者，我已经使用了很长一段时间，并且正在工作。它的代码是：

fbRisingEdge(CLK := bExecute);
CASE eFileWriteStep OF
    E_FileWriteStep.IDLE :
        IF fbRisingEdge.Q THEN
            nFileHandle := 0;
            bBusy := TRUE;
            eFileWriteStep := E_FileWriteStep.OPEN;
            nFileWriteSubStep := 0;
        END_IF

    E_FileWriteStep.OPEN :
        CASE nFileWriteSubStep OF
            0 :
                fbFileOpen(sPathName := sPathName, bExecute := FALSE);
                fbFileOpen(sPathName := sPathName, bExecute := TRUE);
                nFileWriteSubStep := nFileWriteSubStep + 1;
            1 :
                fbFileOpen(bExecute := FALSE);
                IF NOT fbFileOpen.bBusy THEN
                    IF fbFileOpen.bError THEN
                        bError := TRUE;
                        eFileWriteStep := E_FileWriteStep.CLEAN;
                        nFileWriteSubStep := 0;
                    ELSE
                        nFileHandle := fbFileOpen.hFile;
                        eFileWriteStep := E_FileWriteStep.WRITE;
                        nFileWriteSubStep := 0;
                    END_IF
                END_IF
            END_CASE

    E_FileWriteStep.WRITE :
        CASE nFileWriteSubStep OF
            0 :
                fbFileWrite(bExecute := FALSE);
                fbFileWrite(hFile := nFileHandle,
                            pWriteBuff := aFileData,
                            cbWriteLen := UDINT_TO_UINT(UPPER_BOUND(aFileData, 1)),
                            bExecute := TRUE);
                nFileWriteSubStep := nFileWriteSubStep + 1;
            1 :
                fbFileWrite(bExecute := FALSE);
                IF NOT fbFileWrite.bBusy THEN
                    IF fbFileWrite.bError THEN
                        bError := TRUE;
                        eFileWriteStep := E_FileWriteStep.CLEAN;
                    ELSE
                        eFileWriteStep := E_FileWriteStep.CLEAN;
                        nBytesWritten := fbFileWrite.cbWrite;
                    END_IF
                nFileWriteSubStep := 0;
                END_IF
        END_CASE

    E_FileWriteStep.CLOSE :
        CASE nFileWriteSubStep OF
            0 :
                fbFileClose(bExecute := FALSE);
                fbFileClose(hFile := nFileHandle, bExecute := TRUE);
                nFileWriteSubStep := 1;
            1 :
                fbFileClose(bExecute := FALSE);
                IF NOT fbFileClose.bBusy THEN
                    IF fbFileClose.bError THEN
                        bError := TRUE;
                    END_IF
                eFileWriteStep := E_FileWriteStep.CLEAN;
                nFileHandle := 0;
                nFileWriteSubStep := 0;
                END_IF
        END_CASE

    E_FileWriteStep.CLEAN :
        IF nFileHandle <> 0 THEN
            eFileWriteStep := E_FileWriteStep.CLOSE;
            nFileWriteSubStep := 0;
        ELSE
            eFileWriteStep := E_FileWriteStep.IDLE;
            bBusy := FALSE;
        END_IF
END_CASE

在开始时，通过上升的边缘激活函数块。要写入的数据由字节数组(aFileData)提供。在这个状态机的末尾，您也有一些清理代码和最终的错误处理。在这段代码中，您还可以看到在继续下一步之前，如何确保前面的步骤成功。

祝好运!

Answer 2

程序中的主要问题是，您只调用函数块一次，就好像它们是正常函数一样。您必须连续调用函数块，并检查它们何时完成其特定的功能。

当连续调用它们时，您应该首先等待繁忙的标志升高，然后等待它降低(并且没有错误)。如果您对两种等待情况都有状态，并且在这两种状态中调用函数块，这将是最简单的。

请记住，这些文件操作函数块与Windows系统一起工作，可能需要一些时间才能完成它们的工作。

顺便说一句，如果在第一个状态2中添加了“非fbOpenFile.bBusy”条件，那么代码示例实际上可能会工作。但是，如果对每个FB的启动和完成使用两个状态，则程序更容易阅读/调试。