无法理解APEX_MAIL的作业如何运行

Question

我目前正在尝试实现类似版本的甲骨文的APEX_MAIL包。我把一切都做好了，但是除非我修改了它，否则我无法使它正常工作。

APEX_MAIL使用的作业称为ORACLE_APEX_MAIL_QUEUE。

BEGIN
DBMS_SCHEDULER.set_attribute( name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', attribute => 'job_action', value => 'APEX_040000.WWV_FLOW_MAIL.PUSH_QUEUE');

DBMS_SCHEDULER.set_attribute( name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', attribute => 'number_of_arguments', value => '2');
DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE( 
         job_name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', 
         argument_position => 1, 
         argument_value => '');
DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE( 
         job_name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', 
         argument_position => 2, 
         argument_value => '');

END; 
/

所以我去这个包看看代码是怎么做的。我假设推送队列会在队列中发送电子邮件。相反，它再次调用相同的工作！

PROCEDURE PUSH_QUEUE( P_SMTP_HOSTNAME IN VARCHAR2 DEFAULT NULL,
                      P_SMTP_PORTNO   IN VARCHAR2 DEFAULT NULL )
IS
BEGIN
    PUSH_QUEUE_BACKGROUND;
END PUSH_QUEUE;


PROCEDURE PUSH_QUEUE_BACKGROUND
IS
BEGIN
    SYS.DBMS_SCHEDULER.RUN_JOB( JOB_NAME => 'ORACLE_APEX_MAIL_QUEUE', USE_CURRENT_SESSION => FALSE );
EXCEPTION
    WHEN OTHERS THEN
        IF SQLCODE <> -27478 THEN
            RAISE;
        END IF;
END PUSH_QUEUE_BACKGROUND;

所以基本上这个工作什么也不做，但是我把它转换为PUSH_QUEUE_IMMEDIATE，它做我认为应该做的事情。

PROCEDURE PUSH_QUEUE_IMMEDIATE( P_FORCE_YN IN VARCHAR2 DEFAULT 'N')
IS
    L_STATUS            NUMBER;
    L_LOCK_HDL          VARCHAR2(128);
    E_DB_SHUTDOWN       EXCEPTION;
    PRAGMA EXCEPTION_INIT(E_DB_SHUTDOWN, -1089);
BEGIN



    WWV_FLOW_DEBUG.ENABLE_DBMS_OUTPUT;



    SYS.DBMS_LOCK.ALLOCATE_UNIQUE( LOCKNAME => 'APEX_MAIL_QUEUE_LOCK', LOCKHANDLE => L_LOCK_HDL);
    L_STATUS := SYS.DBMS_LOCK.REQUEST( LOCKHANDLE        => L_LOCK_HDL,
                                   LOCKMODE          => SYS.DBMS_LOCK.X_MODE,
                                   TIMEOUT           => 0,
                                   RELEASE_ON_COMMIT => FALSE );
    WWV_FLOW_DEBUG.INFO('APEX Mail Lock status: ' || L_STATUS );




    IF L_STATUS = 0 THEN

        FOR C1 IN ( SELECT   ID, MAIL_SEND_COUNT, LAST_UPDATED_ON
                      FROM WWV_FLOW_MAIL_QUEUE
                     ORDER BY MAIL_SEND_COUNT, LAST_UPDATED_ON) LOOP
            BEGIN
                WWV_FLOW_DEBUG.INFO( 'Pushing email: ' || C1.ID );







                IF  (C1.MAIL_SEND_COUNT = 0) OR (NVL(P_FORCE_YN,'N') = 'Y') OR
                   (C1.MAIL_SEND_COUNT > 0 AND (POWER(2,C1.MAIL_SEND_COUNT)/(60*24) + C1.LAST_UPDATED_ON) < SYSDATE) THEN
                    BACKGROUND( P_ID => C1.ID );
                END IF;
                WWV_FLOW_DEBUG.INFO( 'Pushed email: ' || C1.ID );
            EXCEPTION
                WHEN OTHERS THEN
                    WWV_FLOW_DEBUG.LOG_EXCEPTION;

                    IF L_LOCK_HDL IS NOT NULL THEN
                        L_STATUS := SYS.DBMS_LOCK.RELEASE( L_LOCK_HDL );
                        WWV_FLOW_DEBUG.INFO('APEX Mail released lock' );
                    END IF;
            END;
        END LOOP;
    END IF;



    IF L_LOCK_HDL IS NOT NULL THEN
        L_STATUS := SYS.DBMS_LOCK.RELEASE( L_LOCK_HDL );
        WWV_FLOW_DEBUG.INFO('APEX Mail released lock' );
    END IF;
EXCEPTION WHEN E_DB_SHUTDOWN THEN 
    NULL;
END PUSH_QUEUE_IMMEDIATE;

我正试图复制APEX_MAIL，但如果我这样做了，我就不会有工作了。谁能指出，在应用程序设置更改或任何其他更改之后，APEX_MAIL是否更改了作业？

提前感谢！

Answer 1

排队可以在您自己的代码中立即发送邮件(在队列中)。这项工作通常称为PUSH_QUEUE_IMMEDIATE。我不知道你的设置是否是安装中的一个错误，或者你网站上的错误。因此，实际上，它将PUSH_QUEUE_IMMEDIATE作为APEX_040000作业在单独的会话中调用。

因为每个人都可以请求立即发送队列中的所有作业，所以通过SYS.DBMS_LOCK.REQUEST确保只有一个会话才能实际执行传输。