为C++程序编写BNFC语法

Question

因此，我正在使用BNFC编写语法来解析c++程序。c++程序如下所示。

// a small C++ program
#include <iostream>

int main()
{
    std::cout << "i";
    return 0;
}

我为此编写的BNF语法如下。

PDefs. Program ::= [Def] ;
terminator Def "" ;
comment "//" ;
comment "/*" "*/" ;
comment "#" ;
DFun. Def ::= Type Id "(" [Arg] ")" "{" [Stm] "}" ;
separator Arg "," ;
terminator Stm "" ;
separator nonempty Id "::" ;
ADecl. Arg ::= Type Id ;
SExp.    Stm ::= Exp ";"              ;
Sids.    Stm ::= Id                   ;
SDecl.   Stm ::= Type Id ";"          ;
SDecls.  Stm ::= Type Id "," [Id] ";" ;
SInit.   Stm ::= Type Id "=" Exp ";"  ;
SReturn. Stm ::= "return" Exp ";"     ;
SWhile.  Stm ::= "while" "(" Exp ")" Stm ;
SBlock.  Stm ::= "{" [Stm] "}" ;
SIfElse. Stm ::= "if" "(" Exp ")" Stm "else" Stm ;
EInt.    Exp15 ::= Integer ;
EDouble. Exp15 ::= Double ;
ETrue.   Exp15 ::= "true" ;
EFalse.  Exp15 ::= "false" ;
EId.     Exp15 ::= Id ;
EApp.    Exp15 ::= Id "(" [Exp] ")" ;
EStr.    Exp15 ::= "\"" Id "\"";
EPIncr.  Exp14 ::= Exp15 "++" ;
EPDecr.  Exp14 ::= Exp15 "--" ;
EIncr.   Exp13 ::= "++" Exp14 ;
EDecr.   Exp13 ::= "--" Exp14 ;
ETimes.  Exp12 ::= Exp12 "*" Exp13 ;
EDiv.    Exp12 ::= Exp12 "/" Exp13 ;
EPlus.   Exp11 ::= Exp11 "+" Exp12 ;
EMinus.  Exp11 ::= Exp11 "-" Exp12 ;
ELs.     Exp9  ::= Exp9 "<<" Exp10 ;
ERs.     Exp9  ::= Exp9 ">>" Exp10 ;
ELt.     Exp9  ::= Exp9 "<"  Exp10 ;
EGt.     Exp9  ::= Exp9 ">" Exp10 ;
ELtEq.   Exp9  ::= Exp9 "<=" Exp10 ;
EGtWq.   Exp9  ::= Exp9 ">=" Exp10 ;
EEq.     Exp8  ::= Exp8 "==" Exp9 ;
ENEq.    Exp8  ::= Exp8 "!=" Exp9 ;
EAnd.    Exp4  ::= Exp4 "&&" Exp5 ;
EOr.     Exp3  ::= Exp3 "||" Exp4 ;
EAss.    Exp2  ::= Exp3 "=" Exp2 ;
coercions Exp 15 ; 
separator Exp "," ;
separator Id "," ;
Tbool. Type ::= "bool" ;
Tdouble. Type ::= "double" ;
Tint. Type ::= "int" ;
Tvoid. Type ::= "void" ;
token Id (letter (letter | digit | '_' )*) ;
token Ids (letter)* ;

我已经为::和左移位操作符编写了规则，这里是<<和>>右移位操作符，但出于某种原因，它没有正确地解析。我做错了什么？

根据我的理解，这应该是可行的，但它给出了这个错误。

syntax error at line 6 before << "i" ; return

Answer 1

您的问题是，std::cout不是Id。它可能是一个[Id] --也就是Ids的列表--因为声明

separator nonempty Id "::" ;

但该声明与后来的声明相冲突。

separator Id "," ;

我对BNFC的了解还不足以预测冲突的结果，但很难想象结果是你想要的。

表达式的语法不使用[Id]；它只允许Id

EId.     Exp15 ::= Id ;
EApp.    Exp15 ::= Id "(" [Exp] ")" ;

因此，限定名std::cout不会被解析为Exp15。

在尝试使用Id列表时，您有两个非常不同的上下文；它们在语法和语义上都不同。因此，您真的不能期望对两者都使用[Id]。

由于您显然希望能够处理名称空间的名称，所以我建议显式地将Name定义为Id的非空::-separated列表，当然，您可以使用[Id]宏而不是自己的定义；这实际上是对风格的判断。对我来说，这似乎不那么清晰，但口味却各不相同。

在另一种情况下--声明--使用[Id]确实是不正确的，尽管它可能足以满足您简化语法的需要。在这里，我建议使用一个新的Declarator非终端，您最初可以将其定义为Id，但最终希望将其扩展为包括指针声明器(*foo)、数组声明器(foo[3])，甚至可能包括函数声明器。使用Declarator非终端，您可以替换

SDecl.   Stm ::= Type Id ";"          ;
SDecls.  Stm ::= Type Id "," [Id] ";" ;

使用

separator nonempty Declarator ","
SDecls.  Stm ::= Type [Declarator] ";" ;

注:取自第7节(宏)中的"LBNF语法形式主义“：

分离器非空Stm ";“； 手段 (:[])::= Stm；(:)Stm ::= Stm“；