Neo4J:子句不能按预期工作

Question

当我执行此查询时，使用Neo4J moovie图：

match (p:Person)-[ai:ACTED_IN]->(m:Movie)
where not (p.name in ['Keanu Reeves'])
return m limit 1

我正在拍摄基努·里夫斯在“矩阵革命”中扮演的角色。我认为查询应该返回基努·里维斯没有参与的电影。我做错了什么？基努不演戏的电影是怎样拍的呢？

Answer 1

Patrick B sch回答可以工作，但它正在(p:Person)和(m:Movie)节点之间构建一个笛卡尔积。

下面的查询将完成相同的工作，但避免笛卡尔产品(我认为以更明确的方式)：

MATCH (m:Movie)
WHERE NOT (m)<-[:ACTED_IN]-(:Person {name : 'Keanu Reeves'})
RETURN m

查询将MATCH所有电影，避免与名称等于Keanu的:Person节点具有关系:ACTED_IN的电影。

更新

来自评论：

如果不仅仅是基努·里维斯，而是基努·里维斯和罗宾·威廉姆斯呢？

然后你就可以：

MATCH (m:Movie)<-[:ACTED_IN]-(p:Person)
WITH m, collect(p) as actors
WHERE NONE (actor in actors WHERE actor.name IN ['Keanu Reeves', 'Robin Williams'])
RETURN m

或者：

MATCH (m:Movie)
WHERE NONE(n in ['Keanu Reeves', 'Robin Williams']
    WHERE (m)<-[:ACTED_IN]-(:Person {name:n}))
RETURN m

Answer 2

如果你想得到基努·里夫斯不演的所有电影，你必须把这种关系排除在结果之外，否则你会得到基努·里维斯和其他演员也参与的电影。

所有基努·里维斯没有演过的电影：

MATCH (p:Person),(m:Movie)
WHERE p.name IN ['Keanu Reeves']
AND NOT ((p)-[:ACTED_IN]->(m))
RETURN m