使用VBA只引用excel表数据体范围的一部分

Question

我找到了在表()中引用整个行/列或单细胞 (e.g. The VBA Guide To ListObject Excel Tables)的解决方案，但没有找到特定的范围。

示例: DataBodyRange of Table1是3列和10行，我需要从每列中的第4-10行绘制数据(通过编程，因为表是动态的，如果添加/删除了列，我希望能够重新绘制图)。

我希望语法类似于

Sub reDrawChart()

Set sourcedata = ActiveSheet.ListObjects("Table1")
Set cht = Worksheets("Sheet1").ChartObjects(1).Chart

'Delete existing series
cht.ChartArea.ClearContents 

'Add new series
With cht.SeriesCollection.NewSeries
    For i = 1 To nColumns
        .Name = sourcedata.HeaderRowRange(i)
        .Values = sourcedata.DataBodyRange(4:10, i) '<-- Touble spot
    Next i
End With

End Sub

但这是行不通的。有没有办法做我想用这一行做的事？我应该绕开它，寻求另一种解决方案吗？

我还想避免使用.Select，因为在Mac上，感觉就像任何让VBA结结巴巴的代码都有50/50的机会崩溃到桌面上。

Answer 1

尝试这个循环而不是您的循环：

    For i = 1 To sourceData.ListColumns.count
      With cht.SeriesCollection.NewSeries
        .name = sourceData.ListColumns(i).name
        .values = sourceData.ListColumns(i).DataBodyRange. _
          Offset(3).Resize(sourceData.ListRows.count - 3)
      End With
    Next i

Answer 2

您可以迭代表的ListColumns，并使用偏移量和调整大小从每个‘`ListColumn’的DataBodyRange中获得特定的行集。

对于第4行到第10行，您需要偏移3行，然后调整7行的大小。如果有趣的行数发生变化，或者如果第一行索引发生变化，则可以在下面的示例代码中调整这些数字：

Option Explicit

Sub TableSection()

    Dim ws As Worksheet
    Dim lst As ListObject
    Dim lcl As ListColumn
    Dim i As Long
    Dim var As Variant

    Set ws = ThisWorkbook.Worksheets("Sheet1") '<-- change to your sheet
    Set lst = ws.ListObjects("Table1") '<-- change to your table

    For Each lcl In lst.ListColumns
        ' change 3 and 7 depending on the rows you are interested in
        var = lcl.DataBodyRange.Offset(3, 0).Resize(7, 1)
    Next lcl

End Sub