mbedtls_net_connect在Arduino IDE中使用ESP32连接到AWS IoT时返回-0x52

Question

在Arduino IDE的帮助下，我试图在我的IoT板中使用一个基本的pubsub示例连接到AWS ESP32。

作为一个基本示例，它确实连接到AWS IoT并发布消息，但是当我将静态IP给程序时，它确实用指定的IP地址连接到wifi (我还将静态IP分配到我路由器中的板的MAC地址)，但是它没有发布消息，并给出了以下错误：

试图连接到SSID: RCB Rocks！连接到wifi

E (37583) aws_iot:失败！mbedtls_net_connect返回-0x52

E (37583) AWS_IOT:错误(-23)连接到*.iot.eu-west-2.amazonaws.com:8883，

试图重新连接

我使用以下代码：

#include <AWS_IOT.h>
#include <WiFi.h>
AWS_IOT hornbill;

char WIFI_SSID[]="RCB Rocks!!!!";
char WIFI_PASSWORD[]="********";
char HOST_ADDRESS[]="************.iot.eu-west-2.amazonaws.com";
char CLIENT_ID[]= "1008";
char TOPIC_NAME[]= "smk";
IPAddress ip(192, 168, 0, 20);
IPAddress gateway(192, 168, 0, 1);
IPAddress subnet(255, 255, 255, 0);
int status = WL_IDLE_STATUS;
int tick=0,msgCount=0,msgReceived = 0;
char payload[512];
char rcvdPayload[512];

void mySubCallBackHandler (char *topicName, int payloadLen, char *payLoad) {
  strncpy(rcvdPayload,payLoad,payloadLen);
  rcvdPayload[payloadLen] = 0;
  msgReceived = 1;
}

void setup() {
  Serial.begin(115200);
  delay(2000);
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(WIFI_SSID);
    WiFi.config(ip,gateway,subnet);
    WiFi.mode(WIFI_STA);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
    // wait 5 seconds for connection:
    delay(5000);
  }

  Serial.println("Connected to wifi");
  if(hornbill.connect(HOST_ADDRESS,CLIENT_ID)== 0) {
    Serial.println("Connected to AWS");
    delay(1000);
    if(0==hornbill.subscribe(TOPIC_NAME,mySubCallBackHandler)) {
      Serial.println("Subscribe Successfull");
    } else {
      Serial.println("Subscribe Failed, Check the Thing Name and Certificates");
      while(1);
    }
  } else {
    Serial.println("AWS connection failed, Check the HOST Address");
    while(1);
  }
  delay(2000);
}

void loop() {
  if(msgReceived == 1) {
    msgReceived = 0;
    Serial.print("Received Message:");
    Serial.println(rcvdPayload);
  }
  if(tick >= 5) {
    // publish to topic every 5seconds
    tick=0;
    sprintf(payload,"Hello from hornbill ESP32 : %d",msgCount++);
    if(hornbill.publish(TOPIC_NAME,payload) == 0) {
      Serial.print("Publish Message:");
      Serial.println(payload);
    } else {
      Serial.println("Publish failed");
    }
  }
  vTaskDelay(1000 / portTICK_RATE_MS);
  tick++;
}

我已经为Arduino ESP32 这里找到了AWS ESP32 SDK，我遵循了本网站中给出的说明。

Answer 1

试图连接SSID: RCB Rocks！连接到wifi

所以你的董事会可以得到一个网络连接。

E (37583) aws_iot:失败！mbedtls_net_connect返回-0x52

这个错误意味着

NET -无法获得给定主机名的IP地址。

要么主机名是错误的，要么您的DNS设置有问题。假设您的程序在不使用静态IP地址时工作，问题必须是在板上的DNS设置。当委员会从DHCP接收到动态IP地址时，DHCP服务器也向其发送DNS设置。如果使用静态IP地址而不是DHCP，则还需要静态设置DNS服务器。

Answer 2

您可能想看看ESP板是否可以使用静态IP连接到互联网。你可以试试这张素描。https://learn.sparkfun.com/tutorials/esp32-thing-hookup-guide#arduino-example-wifi

我的板上也有同样的问题，如果我用铬连接到无线，我就会得到DNS_PROBE_FINISHED_NO_INTERNET。更改为不同的网络解决了问题。

Answer 3

我知道这很古老，但是将Wifi.begin()移到for循环之外对我来说是个窍门：

WiFi.config(ip,gateway,subnet);
WiFi.mode(WIFI_STA);

Serial.print("Attempting to connect to SSID: ");
Serial.println(WIFI_SSID);

// Connect to WPA/WPA2 network. Change this line if using open or WEP network:
WiFi.begin(WIFI_SSID, WIFI_PASSWORD);

while (WiFi.status() != WL_CONNECTED) {
  Serial.print(".");
  delay(500);
}

Serial.print("connected.");