在数据表中检索切片器的设置

Question

我甚至不确定这是否有可能。但我使用的是一个相当大的数据表，主要是由切割机控制的。当我提取这个数据表时，我希望在头中有切片器的设置和提取的日期/时间(作为正确的切割机设置的额外确认，当然也是提取数据的时间点)。

谷歌不知道答案，而且由于我的google-fu倾向于强大，我来这里寻求建议。

这有可能吗？最好是在VBA里做。

Answer 1

啊找到了。

使用下面的代码创建了一个PublicFunction，它将显示所选的切片器值。

Public Function GetSelectedSlicerItems(SlicerName As String) As String
Dim oSc As SlicerCache
Dim oSi As SlicerItem
Dim lCt As Long
On Error Resume Next
Application.Volatile
Set oSc = ThisWorkbook.SlicerCaches(SlicerName)
If Not oSc Is Nothing Then
    For Each oSi In oSc.SlicerItems
        If oSi.Selected Then
            GetSelectedSlicerItems = GetSelectedSlicerItems & oSi.Name & ", "
            lCt = lCt + 1
        ElseIf oSi.HasData = False Then
            lCt = lCt + 1
        End If
    Next
    If Len(GetSelectedSlicerItems) > 0 Then
        If lCt = oSc.SlicerItems.Count Then
            GetSelectedSlicerItems = "All"
        Else
            GetSelectedSlicerItems = Left(GetSelectedSlicerItems, Len(GetSelectedSlicerItems) - 2)
        End If
    Else
        GetSelectedSlicerItems = "No items selected"
    End If
Else
    GetSelectedSlicerItems = "No slicer with name '" & SlicerName & "' was found"
End If
End Function